How to make a PlotMarker with two colors?

Question

I have a very simple question. I'd like to display two points -- that currently appear on top of each other in a ListPlot -- as (replace them by) a single plot marker with two colours, one for each half of the marker, say upper/lower halves. Since I am using the default plot markers, I'm just after a disk of precisely the same size as the one from PlotMarkers -> Automatic with adjustable colours for the upper and lower halves. Then I can easily match the size and colours with the rest of my plot. How does one make this marker?

Here's a toy example to play around with: ListPlot[{Table[1/n,{n,10}],ConstantArray[1/10,10]}]. In this case I'd like the last point to have the first default colour (upper half) and second default colour (lower half).

Answer 1

You may draw a marker consisting of 2 half disks with the corresponding colors:

ListPlot[{Table[1/n, {n, 10}], ConstantArray[1/10, 10]}, 
 Epilog -> {Blue, Disk[{10, 0.1}, {0.1, 0.008}, {0, Pi}], Orange, , 
   Disk[{10, 0.1}, {0.1, 0.008}, {Pi, 2 Pi}]}]

Answer 2

Here's an attempt using the PolygonMarkers resource function. The hfm function is adapted from the Neat Examples section of the documentation of that resource function.

sin = Table[{x, Sin[x]}, {x, 0, 1.5 Pi, Pi/9}];
line = Table[{x, x - 1.22}, {x, 0, 1.5 Pi, Pi/9}];

ClearAll[hfm]
hfm[name_String, side_String : "Right", size_ : 9] :=
 Module[
  {checkSide = If[side === "Right", Negative, Positive, Negative]},
  Show[
   ResourceFunction["PolygonMarker"][name, Offset@size, {FaceForm[None], Dynamic@EdgeForm[{CurrentValue["Color"], AbsoluteThickness[1], Opacity[1]}]}],
   ResourceFunction["PolygonMarker"][name, Offset@size, EdgeForm[None]] /. {x_?checkSide, y_?NumericQ} :> {0, y}
   ]
  ]

ListPlot[
 {sin, line},
 PlotMarkers -> {hfm["Circle", "Right"], hfm["Circle", "Left"]},
 Joined -> True,
 Frame -> True, Axes -> False,
 PlotLegends -> PointLegend[{"sine", "line"}, LegendMarkerSize -> {40, 30}]
]

Answer 3

A possibility could be:

t = Table[{x, Sin[x]}, {x, 0, 2 π, π/10}];
m1 = Graphics[{
    Orange, Disk[{0, 0}, Offset[{4, 4}], {0, \[Pi]}]
    }
   , PlotRangePadding -> Scaled[.05]
   ];

m2 = Graphics[{
    Red, Disk[{0, -1}, Offset[{4, 4}], {\[Pi], 2 \[Pi]}]
    }
   , PlotRangePadding -> Scaled[.05]
   ];

ListPlot[{t, t}, PlotMarkers -> {m1, m2}, 
 PlotRangePadding -> Scaled[.05]]