Question in Derivatives and TableForm

Question

Using the TableForm command, I want to find the derivatives up to the fourth order of the function $f(x)=\cos{x^2}/x$ and give the results in Matrix form.

Answer 1

Many ways to do this. One is

f[x_] := Cos[x^2]/x
data = {TraditionalForm[HoldForm@D[f[x], {x, #}]], 
     TraditionalForm[D[f[x], {x, #}]]} & /@ Range[4];
PrependTo[data, {Row[{TraditionalForm[HoldForm@f[x]], "=", 
    TraditionalForm[f[x]]}], "output"}]
Grid[data, Frame -> All]

You did not say if this is for display only or not. If you want to use the data, then you can remove the Grid part. If it is for display only, you can also use TeXForm and MaTeX to make nice Latex table with caption title and figure numbers to include in your latex document so you can reference the table from other places in the document.

Answer 2

Clear["Global`*"]

f[x_] := Cos[x^2]/x

Using MatrixForm (note that the "forms" are not included in the scope of the definition of mat)

(mat = NestList[{#[[1]] + 1, Simplify[D[#[[2]], x]]} &, {0, f[x]}, 
     4]) // TraditionalForm // MatrixForm

Using TableForm

TableForm[mat, 
  TableHeadings -> {None, {n, 
     Superscript[f, "(n)"][x]}}] // TraditionalForm

Answer 3

Using FoldList while calculating derivs in addition to mostly borrowed formatting techniques:

f[x_] := Cos[x^2]/x
n = 5;
derivs = FoldList[D[#, x] &, f[x], Range[n]];
ops = TraditionalForm@HoldForm[Derivative[#][f][x]] & /@ Range[0, n];
data = Transpose@{TraditionalForm /@ Range[0, n], ops, 
    TraditionalForm /@ derivs};

Grid[#, Frame -> All
   , Alignment -> {Center, Center}
   , Spacings -> {1, 2}
   , ItemSize -> {{Scaled[.1], Scaled[.1], Scaled[0.8]}}
   ] &@
 PrependTo[data
  , TraditionalForm /@ {"n", Superscript[f, "(n)"][x], "Output"}
  ]