How to fill horizontally between two lines in ListPlot?

Question

I'm a beginner at Mathematica, and I'm trying to figure out how to fill between two lines horizontally. Consider the toy example

Plot[{ConditionalExpression[2*x - 2, 2 < x < 6], ConditionalExpression[2*x + 2, x < 4]}, {x, 0, 10}, PlotRange -> {{0, 11}, {0, 11}}, Filling -> {1 -> {2}}]

Is there some easy way to fill horizontally between the two lines (so the whole area between the lines from y=2 to y=10 in the example is filled)? This whole thing is to be embedded in a bigger plot, so I cant for example add points outside of this plot to extend the top line and thus the coloring.

Answer 1

$Version

(* "13.1.0 for Mac OS X x86 (64-bit) (June 16, 2022)" *)

Clear["Global`*"]

Split each of the lines into two segments and cycle the PlotStyle

Plot[{
  ConditionalExpression[2*x - 2, 2 < x < 4],
  ConditionalExpression[2*x + 2, 0 < x < 2],
  ConditionalExpression[2*x - 2, 4 < x < 6],
  ConditionalExpression[2*x + 2, 2 < x < 4]},
 {x, 0, 10},
 PlotRange -> {{0, 11}, {0, 11}},
 Filling -> {1 -> {4}, 2 -> 2, 3 -> 10},
 FillingStyle -> LightBlue,
 PlotStyle -> (ColorData[97] /@ {1, 2}),
 PlotLegends -> Placed[
   {HoldForm[2*x - 2], HoldForm[2*x + 2], None, None},
   {.7, .5}]]

Answer 2

Something like:

dat1 = Table[ {i, RandomReal[{-1, 1}]}, {i, 10}];
dat2 = Table[ {i, 2 + RandomReal[{-1, 1}]}, {i, 2, 12}];
ListLinePlot[{dat1, dat2}, Filling -> {1 -> {2}}]

Addendum

If you want the shading to connect the first points and the last points, it gets a bit more complex:

SeedRandom[4];
dat1 = Table[{i, RandomReal[{-1, 1}]}, {i, 10}];
dat2 = Table[{i, 2 + RandomReal[{-1, 1}]}, {i, 2, 12}];

ListLinePlot[{dat1, 
  dat2, {dat1[[1]], dat2[[1]]}, {dat1[[-1]], dat2[[-1]]}}, 
 Filling -> {1 -> {{2}, 
     LightBlue}, {1 -> {{3}, {LightBlue, 
       LightBlue}}}, {2 -> {{4}, {LightBlue, LightBlue}}}}, 
 PlotStyle -> {Blue, Orange, White, White}]

Answer 3

• construct two lines to make a closed curve and then use BoundaryDiscretizeGraphics to get a region.

Clear[f, g, plot1, plot2, pts1, pts2, reg];
f[x_] = ConditionalExpression[2*x - 2, 2 < x < 6];
g[x_] = ConditionalExpression[2*x + 2, x < 4];
plot1 = Plot[f[x], {x, 0, 10}, PlotStyle -> Red];
plot2 = Plot[g[x], {x, 0, 10}, PlotStyle -> Green];
pts1 = Cases[plot1, Line[pts_] :> pts, Infinity][[1]];
pts2 = Cases[plot2, Line[pts_] :> pts, Infinity][[1]];
reg = Graphics[{Line[pts1], Line[pts2], 
     Line[{pts1[[-1]], pts2[[-1]]}], Line[{pts1[[1]], pts2[[1]]}]}] //
    BoundaryDiscretizeGraphics;
Show[reg, plot1, plot2, Axes -> True]

• test another two functions which does not intersection each other.

Clear[f, g, plot1, plot2, pts1, pts2, reg];
f[x_] = ConditionalExpression[1/x - 2, 2 < x < 6];
g[x_] = ConditionalExpression[1/4 x^2 + 2, x < 4];
plot1 = Plot[f[x], {x, 0, 10}, PlotStyle -> Red];
plot2 = Plot[g[x], {x, 0, 10}, PlotStyle -> Green];
pts1 = Cases[plot1, Line[pts_] :> pts, Infinity][[1]];
pts2 = Cases[plot2, Line[pts_] :> pts, Infinity][[1]];
reg = Graphics[{Line[pts1], Line[pts2], 
     Line[{pts1[[-1]], pts2[[-1]]}], Line[{pts1[[1]], pts2[[1]]}]}] //
    BoundaryDiscretizeGraphics;
Show[reg, plot1, plot2, Axes -> True]

• for ListPlot.

Clear[pts1, pts2, graphics, reg]
SeedRandom[1];
pts1 = SortBy[RandomPoint[Rectangle[{-1, 4}, {10, 5}], 10], First];
pts2 = SortBy[RandomPoint[Rectangle[{-1, 0}, {10, 2}], 10], First];
graphics = 
  Graphics[{Line[pts1], Line[pts2], Line[{pts1[[-1]], pts2[[-1]]}], 
    Line[{pts1[[1]], pts2[[1]]}]}];
reg = graphics // BoundaryDiscretizeGraphics;
Show[reg, ListLinePlot[{pts1, pts2}, PlotStyle -> {Red, Green}], 
 Axes -> True]