Why do I get a different answer from Mathematica when calculating this integral?

Question

I am curious and confused about the solution of this integral. $$\int_{t}^{T}(1-e^{\alpha(s-T)})e^{\alpha(t-s)}ds$$

When I use Mathematica with this code

ClearAll["Global`*"]
Integrate[(1 - Exp[α (s - T)])*Exp[α (t - s)], {s, t, 
  T}, Assumptions -> 0 <= t <= T, Assumptions -> α > 0]  

the output is

(1 + E^((t - T) α) (-1 + t α - T α))/α

but apparently the solution to the integral should be $$\frac{1}{\alpha}(1-e^{\alpha(t-T)})^2$$ What am I doing wrong?

Answer 1

To check the Mma result (which is not absolutely straightforwardly here) let us first get the indefinite integral:

Integrate[(1 - Exp[α (s - T)])*Exp[α (t - s)], s, 
  Assumptions -> {α > 0, 0 <= t <= T, T > 0, t > 0}] // 
 Simplify[#, {α > 0, 0 <= t <= T, T > 0, t > 0}] &

(*  -((E^((-s + t) α) + E^((t - T) α) s α)/α)   *)

To better visualize it I show also the image:

Let us make sure that it is right:

D[-((E^((-s + t) α) + 
    E^((t - T) α) s α)/α), s] // 
 Simplify[#, {α > 0, 0 <= t <= T, T > 0, t > 0}] &

(*  E^((-s + t) α) - E^((t - T) α)  *)

which is equal to your original function:

(1 - Exp[α (s - T)])*Exp[α (t - s)] // 
 Simplify[#, {α > 0, 0 <= t <= T, T > 0, t > 0}] &

(*  E^((-s + t) α) - E^((t - T) α)  *)

Now, let us apply the Newton-Leibnitz theorem directly:

(-((E^((-s + t) α) + 
      E^((t - T) α) s α)/α) /. 
    s -> T) - (-((
     E^((-s + t) α) + 
      E^((t - T) α) s α)/α) /. s -> t) // 
 Simplify[#, {α > 0, 0 <= t <= T, T > 0, t > 0}] &

(* (1 + E^((t - T) α) (-1 + t α - T α))/α  *)

You can make sure that the result is equal to that obtained by Mma for the definite integral

Integrate[(1 - Exp[α (s - T)])*Exp[α (t - s)], {s, t, 
   T}, Assumptions -> {α > 0, 0 <= t <= T, T > 0, t > 0}] // 
 Simplify[#, {α > 0, 0 <= t <= T, T > 0, t > 0}] &

(*  (1 + E^((t - T) α) (-1 + t α - T α))/α  *)

Thus, as @Nasser wrote in his comment, Mma gives the right result.

Have fun!

Answer 2

Rewrite: Initial post had a blunder.

This appears to be the answer:

f[n_] := α^(1-n) - (α^(1-n) Gamma[n, (T-t) α]) / Gamma[n];

It agrees with the first sixteen terms:

assum = (0 <= t <= s <= T) && α > 0 && n > 0 && 
   n ∈ Integers;
foo = NestList[
    Integrate[(# /. t -> s)*Exp[α (t - s)], {s, t, T}, 
      Assumptions -> assum] &,
    (1 - Exp[α (t - T)]),
    15]; // AbsoluteTiming
(*  {127.602, Null}  *)

foo - Table[f[n], {n, Length@foo}] // FunctionExpand // 
 FullSimplify[#, assum] &
(*  {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}  *)

Proof left as an exercise.