PolarPlot[{theta, Exp[theta]}, {theta, 1, 1.2},
Frame -> True,
PlotLegends -> "Expressions"
]
Looked into the filling option but does not seem to be able to make it work in the case...
Trying to make a visual of this
$\begingroup$
$\endgroup$
Add a comment
|
3 Answers
$\begingroup$
$\endgroup$
1
One way is to use ParametricPlot, which let's us introduce a second variable that lerps between the expressions:
ParametricPlot[
(w*θ + (1-w)*Exp[θ]){Cos[θ], Sin[θ]},
{θ, 1, 1.2},
{w, 0, 1},
AspectRatio -> 1,
Axes -> False
]
answered Mar 19, 2022 at 12:37
-
1$\begingroup$ +1 But to more closely represent just adding filling use
Show[ ParametricPlot[(w*θ+ (1 - w)*Exp[θ]) {Cos[θ], Sin[θ]}, {θ, 1, 1.2}, {w, 0, 1}, AspectRatio -> 1, Axes -> False, BoundaryStyle -> None], PolarPlot[{theta, Exp[theta]}, {theta, 1, 1.2}, Frame -> True, PlotLegends -> "Expressions"]]$\endgroup$ Commented Mar 19, 2022 at 14:04
$\begingroup$
$\endgroup$
2
You can use ParametricRegion and overlay it on your original plot using Show:
Show[
Region[ParametricRegion[(w*θ + (1 - w)* Exp[θ]) {Cos[θ], Sin[θ]}, {{θ, 1, 1.2}, {w, 0, 1}}]]
, PolarPlot[{θ, Exp[θ]}, {θ, 1, 1.2}, Frame ->True, PlotLegends -> "Expressions"]
]
answered Mar 19, 2022 at 12:53
-
1$\begingroup$ +1 However the
Regionpartially obscures the plot. Recommend that you reverse the order in theShow, i.e.,Show[Region[ParametricRegion[(w*θ + (1 - w)*Exp[θ]) {Cos[θ], Sin[θ]}, {{θ, 1, 1.2}, {w, 0, 1}}], Frame -> True], PolarPlot[{θ, Exp[θ]}, {θ, 1, 1.2}, Frame -> True, PlotLegends -> "Expressions"]]$\endgroup$ Commented Mar 19, 2022 at 14:18 -
$\begingroup$
$\endgroup$
3
plot = PolarPlot[{theta, Exp[theta]}, {theta, 1, 1.2}, Frame -> True,
PlotLegends -> "Expressions",PlotRange -> All];
{pts1, pts2} = Cases[plot, Line[a_] :> a, Infinity];
area = Polygon[Join[pts1, Reverse@pts2]];
Show[plot, Graphics[{Cyan, area}]]
area // Area
0.787193
-
$\begingroup$ The original code similar with @kglr
ParametricPlot[θ*{Cos[θ], Sin[θ]}*(1 - s) + E^θ {Cos[θ], Sin[θ]}*s, {θ, 1, 1.2}, {s, 0, 1}, PlotStyle -> Brown, MeshFunctions -> {#4 &}, Mesh -> {{{0, Directive[AbsoluteThickness[4], Green]}, {1, Directive[AbsoluteThickness[4], Red]}}}, BoundaryStyle -> None, Frame -> True, Axes -> False, PlotRange -> All]$\endgroup$– cvgmtCommented Mar 19, 2022 at 14:06 -
$\begingroup$ +1 However, the region partially obscures the original plot. Recommend that you reverse the order in
Show, i.e.,Show[Graphics[{Cyan, area}, Frame -> True], plot]$\endgroup$ Commented Mar 19, 2022 at 14:12 -