CoefficientRules numericizing parameters

Question

I ran into a problem with CoefficientRules behaving differently with exact and numerical coefficients, where in the numerical case it behaves as if the entire expression had an N[...] around it, numericizing all numbers, including indices.

E.g.,

CoefficientRules[A[0] x + A[1] y + 1, {x, y}]

works as intended, but

CoefficientRules[A[0] x + A[1] y + 1., {x, y}]

does not, as it has A[0.] and A[1.] in the result.

Is there an easy way to stop this from happening or to convert back the wrong results to their correct form?

Edit: one general workaround I found is to use subscripts such as Subscript[A,0] instead of expressions that could be interpreted as function evaluations. That also works with multiple indices and non-integer parameters, for which some of the other suggested workarounds do not.

Answer 1

I prefer Daniel Lichtblau's workaround, which can be done temporarily:

Block[{A},
 SetAttributes[A, NHoldAll];
 CoefficientRules[A[0] x + A[1] y + 1., {x, y}]    (* A N-protected *)
 ]
CoefficientRules[A[0] x + A[1] y + 1., {x, y}]
(*
  {{1, 0} -> A[0], {0, 1} -> A[1], {0, 0} -> 1.}   (* A N-protected *)
  {{{1, 0} -> A[0.], {0, 1} -> A[1.], {0, 0} -> 1.}
*)

Another way is to use CoefficientList and convert the output to rules:

With[{coeff = 
   SparseArray@CoefficientList[A[0] x + A[1] y + 1., {x, y}]},
 Thread[coeff@"NonzeroPositions" - 1 -> coeff@"NonzeroValues"]
 ]
(*
  {{0, 0} -> 1., {0, 1} -> A[1], {1, 0} -> A[0]}  
*)

With CoefficentList exact numeric coefficients are left intact:

Block[{A},
 SetAttributes[A, NHoldAll];
 CoefficientRules[A[0] x + Sqrt[2] A[1] y + 1., {x, y}]
 ]
(*  {{1, 0} -> A[0], {0, 1} -> 1.41421 A[1], {0, 0} -> 1.}  *)

With[{coeff = 
   SparseArray@
    CoefficientList[A[0] x + Sqrt[2] A[1] y + 1., {x, y}]},
 Thread[coeff@"NonzeroPositions" - 1 -> coeff@"NonzeroValues"]
 ]
(*  {{0, 0} -> 1., {0, 1} -> Sqrt[2] A[1], {1, 0} -> A[0]}  *)