Split in non-overlapping sub-lists with elements within an interval from the first member

Question

I want to split a large ordered list into consecutive non-overlapping sub-lists, such that all elements are within an interval from the first member of the sub-list . For example:

list={{1,x},{2,x},{3,x},{4,x},{5,x},{8,x},{13,x},{16,x},{17,x}}

And I want to split it so that all first elements are within an interval of 3. The desired result is this:

result={{{1,x},{2,x},{3,x}},{{4,x},{5,x}},{{8,x}},{{13,x}},{{16,x},{17,x}}}

Notice that the interval is relative to the first member of the sub-list and the final result is non-overlapping. So, for example, {{2,x},{3,x},{4,x}} is not in the result.

Answer 1

Here is a way using SplitBy:

split[l:{__}, m_] :=
  Module[{e = l[[1, 1]] + m}
  , SplitBy[l, If[#[[1]] < e, e, e = #[[1]] + m]&]
  ]

split[list, 3]

(* {{{1,x},{2,x},{3,x}},{{4,x},{5,x}},{{8,x}},{{13,x}},{{16,x},{17,x}}} *)

Answer 2

Three variations on WReach's key idea:

ClearAll[splitA]
splitA[l : {__}, m_] := Module[{e = l[[1, 1]] + m},
 Last @ Reap @ Scan[Sow[#, If[#[[1]] < e, e,  e = #[[1]] + m]] &, l]]

splitA[list, 3]

 {{{1, x}, {2, x}, {3, x}}, 
  {{4, x}, {5, x}}, 
  {{8, x}}, 
  {{13, x}}, 
  {{16, x}, {17, x}}}

ClearAll[splitB]
splitB[l : {__}, m_] := Module[{e = l[[1, 1]] + m},
  Split[l, Or[#2[[1]] < e, e = #2[[1]] + m] &]]

ClearAll[splitC]
splitC[l : {__}, m_] := Module[{e = l[[1, 1]] + m},
  SplitBy[l, Or[#[[1]] < e, e = #[[1]] + m] &]]

splitA[list, 3] == splitB[list, 3] == splitC[list, 3]

True

Answer 3

res = 
  Catenate @ Map[Partition[#, UpTo @ 3] &] @ 
    Split[list, #2[[1]] - #1[[1]] == 1 &];

res == result

(* True *)

Answer 4

list = {{1, x}, {2, x}, {3, x}, {4, x}, {5, x}, {8, x}, {13, x}, {16, x}, {17, x}};

---

Using SequenceCases:

ConsecutiveQ = Most[#] == Rest[#] - 1 &;

p = Map[Splice@Partition[#, UpTo@3] &];

res = p@SequenceCases[list, x : {__} /; ConsecutiveQ@x[[All, 1]]]

res === result

(*True*)