Publish to Cloud with accompanying stylesheet

Question

Is it possible to Publish to Cloud with an accompanying user-defined stylesheet? So that anyone who clicks on the link will see it with the correct stylesheet.

I'm not talking about using stylesheets on your own, editable, version of the document on the cloud, as in this question.

The use case is that I have made my own stylesheet "mystylesheet.nb" which extends "default.nb", and I have a notebook, which uses this stylesheet, and I want to publish this notebook to the cloud so that anyone can view it. But it should display on their screens with the correct stylesheet "mystylesheet.nb" being used.

Update: When I try Rolf Mertig's helpful Button below, it doesn't seem to work. Here is how the notebook appears on my Mathematica desktop application (it has been styled by my stylesheet):

Then I click the magic "Embed Stylesheet explicitly" Button, and then click "Publish to Cloud" from the File menu. Here is how it looks like on the cloud, in my Chrome browser:

The reason for the problem, in this case, can be found as follows. If, on the cloud version, you type in Options[SelectedNotebook[]] one finds that my stylesheet options were not loaded line-by-line in explicit form, but were rather left as a file eg. StyleDefinitions -> UserStyle.nb.

Answer 1

If you load "mystyle.nb", e.g. by Get, it is easy to do what you want:

myStyle = 
  Export["mystyle.nb", 
   Notebook[{Cell[StyleData[StyleDefinitions -> "Default.nb"]], 
     Cell[StyleData["Notebook"], Background -> Red], 
     Cell[StyleData["Input"], CellFrame -> True]}]];
myNB = CreateDocument[ExpressionCell[Defer[1 - 2], "Input"]];
SetOptions[myNB, StyleDefinitions -> Get[myStyle]]
CloudDeploy[myNB] // SystemOpen

results in

Suppose your "mystylesheet.nb" is in the same folder as your notebook, or somewhere on $Path, then I would first generate a Button by executing this code in a different notebook:

Button["Embed StyleSheet explicitly",
  Module[{nb = SelectedNotebook[], styleNB},
    styleNB = FileNames[
      Replace[ CurrentValue[nb, StyleDefinitions], 
        Notebook[{Cell[StyleData[
          StyleDefinitions -> myStyleFile_String]]}, __] :>myStyleFile],
          Prepend[$Path, NotebookDirectory[nb]]
    ] /. {s_String} :> s;
    If[ FileExistsQ[styleNB]
      ,
      SetOptions[nb, StyleDefinitions -> Get @ styleNB
    ];
   NotebookSave[nb];
   MessageDialog[TextCell[styleNB <> " has been embedded", "Title"], 
      WindowMargins -> CurrentValue[InputNotebook[], WindowMargins]]]
   ]
  ] // 
 (CreatePalette[#, WindowMargins -> (
    AbsoluteCurrentValue[SelectedNotebook[], WindowMargins
    ] {{0, 1}, {1, 0}} + {{1, 0}, {0, 1}} MousePosition[])] &)

and then you first click on the main notebook you want to publish, then click on the button and then you can use the standard menu item "Publish to Cloud..." from the File menu. You may also save the Button notebook for later use. Of course something like this should automatically happen inside NotebookToolsOpenCloudPublishDialog`, but that is something the Wolfram developers will certainly do for the next version (I hope). It should be easy to generalize my short fix for more complicated private style sheets.