Evaluation of a hypergeometric function

Question

I am working with functions like

f[z_] = Hypergeometric2F1[4, 4, 8, z]

Here is a plot of this function over the interval $z \in [0,1]$:

Plot[f[z], {z, 0, 1}]

As you can see, Mathematica has difficulties evaluating it in the region $z \approx 0$. This is surprising, because the hypergeometric function admits by definition a simple series expansion around $z = 0$, $$ f(z) = \sum_{n = 0}^\infty \frac{7!}{(3!)^2} \frac{(n+1)(n+2)(n+3)}{(n+4)(n+5)(n+6)(n+7)} z^n = 1 + 2 z + \frac{25}{9} z^2 + \ldots $$

The problem is that Mathematica does not use this defining property of the hypergeometric function, but instead it "simplifies" it to

f[z] = (140*(-60*z + 60*z^2 - 11*z^3 - 60*Log[1 - z] + 90*z*Log[1 - z] - 36*z^2*Log[1 - z] + 3*z^3*Log[1 - z]))/(3*z^7)

and it turns out that cancellations between large numbers occur in this expression when $z \approx 0$.

How can I instruct mathematica to not perform this "simplification" in general? Is there a way I can use the command Hold or something similar?

What I want to do eventually is evaluate numerically some integrals in which $f(z)$ appears in the integrand, so I need a robust way of evaluating the function over the interval $z \in [0,1]$.

Answer 1

The commands

Plot[Hypergeometric2F1[4, 4, 8, z], {z, 0, 1}, WorkingPrecision -> 15]

or/and

f[z_] = Hypergeometric2F1[4, 4, 8, z]; Plot[f[z], {z, 0, 1}, WorkingPrecision -> 25]

do the job.

Addition.

Integrate[Hypergeometric2F1[4, 4, 8, z], {z, 0, 1}]

$\frac{133}{9} $

NIntegrate[Hypergeometric2F1[4, 4, 8, z], {z, 0, 1}, WorkingPrecision -> 15]

$14.7777777777777 $

Answer 2

I'm not sure if this will help, but it might be worth checking out.

f[z_] = Hypergeometric2F1[4, 4, 8, z] // FunctionExpand
(*(140 (-(11 z^3) + 3 z^3 Log[1 - z] + 60 z^2 - 36 z^2 Log[1 - z] - 
   60 z + 90 z Log[1 - z] - 60 Log[1 - z]))/(3 z^7)*)

<< PrecisionPlot`

PrecisionPlot[f[z], {z, 0, 1}]

You can get PrecisionPlot from http://library.wolfram.com/infocenter/MathSource/715/

The problem seems to be precision rather than the function Mathematica uses. Compare:

f[1/1000] // N
(*2.47395*10^8*)

with

f[1/1000] // N[#, 50] &
(*1.0020027811148271960352800702800453256995763414200*)

and while f[0] doesn't work, the limit does.

Limit[f[z], z -> 0]
(*1*)

Although PrecisionPlot is smoother, it doesn't really do a great job of matching the very small values of z.