2
$\begingroup$

I need help in evaluating the following tricky summation mainly involving a product of two Kummer's confluent hypergeometric function, ${}_1 F_1(a;b;z)$. Is there some identity of ${}_1 F_1(a;b;z)$ that I could use to simplify the product: ${}_1 F_1(1+k;1;b)\times{}_1 F_1(1+n-k;1+n-n';c)$ in the summation?

$ f(n,n';a,b,c)=\sum_{k=0}^{n} \frac{a^{2 k} \, _1F_1(1+k;1;b) \, _1F_1\left(1+n-k;1+n-n';c\right)}{k! \left(n'-k\right)!}$

where, $a$, $b$, and $c$ are constants.

Here is the Mathematica code.

f[n_, n1_, a_, b_, c_] := Sum[(a^(2 k) Hypergeometric1F1[1 + k, 1, b] Hypergeometric1F1[1 - k + n, 1 + n - n1, c])/(k! (-k + n1)!), {k, 0, n}]

Note that in the code, the variable, $n1=n'$.

I'm looking to get a closed-form expression for this summation if it converges. I came across this summation while working on a bigger physics research problem.

$\endgroup$
10
  • 1
    $\begingroup$ Not sure if this is a MMA question though. Have you tried asking in the math forum instead? $\endgroup$
    – MarcoB
    Feb 1, 2022 at 17:34
  • 3
    $\begingroup$ Sometimes plugging in integer values for $k$ (and $n$ and $n'$) will show a pattern as opposed to going for a direct symbolic result. For example, when n1=1, the whole sum simplifies to Exp[b + c] (n (1 + a^2 (1 + b)) + c)/n. So maybe asking how Mathematica could search for patterns to simplify your equation (or at least parts of it) might get you more help in this forum. $\endgroup$
    – JimB
    Feb 1, 2022 at 17:39
  • $\begingroup$ @MarcoB Yes, I have also asked the question in the math forum. $\endgroup$
    – JayanthJ
    Feb 1, 2022 at 22:12
  • 2
    $\begingroup$ But if you plug in 1, 2, 3,..., 10 for n while leaving n1=1, you'll see the pattern and the result I gave in my initial comment. (If there's a limited range of values for $n$ and $n'$ that you're interested in, that would be helpful to know. Should I assume you always want $n \geq n'$ ?) $\endgroup$
    – JimB
    Feb 1, 2022 at 22:30
  • 1
    $\begingroup$ You might want to consider a restriction as f[2,3,a,b,c] results in Indeterminate with the warning Infinity::indet: Indeterminate expression ComplexInfinity+ComplexInfinity+ComplexInfinity encountered. $\endgroup$
    – JimB
    Feb 2, 2022 at 0:13

1 Answer 1

4
$\begingroup$

More of an extended comment.

This is following the logic of finding patterns, which I love, and is also suggested by @JimB. Below I give my approach to this kind of problems. By the way, from the two concrete cases I examined it seems that there should be a general formula in terms of n and n1.

The logic is that we want to re-sum in two variables. We break it down to baby steps as follows.

We assume for concreteness $n \geq n^{\prime}$.

We define the function

f[n_, n1_, a_, b_, c_] := 
 Sum[(a^(2 k) Hypergeometric1F1[1 + k, 1, b] Hypergeometric1F1[
      1 - k + n, 1 + n - n1, c])/(k! (-k + n1)!), {k, 0, n}]

We generate data from the above like so:

Table[f[n, 1, a, b, c], {n, 1, 10}]

Then, we find a pattern in the increasing value of n by using

FindSequenceFunction[{1, 1/2, 1/3, 1/4, 1/5}, n]

We write down our conjectured formula

guess1[n_, a_, b_, c_] := 
 a^2 (1 + b) Exp[b + c] + (1 + c/n) Exp[b + c]

and for our peace of minds we verify our analytic guess against higher values of n compared to the ones we used in order to guess our answer.

Table[f[n, 1, a, b, c] - guess1[n, a, b, c], {n, 1, 21}]

The result is

{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}

as it should.

I am providing another example for clarity. The n1=2 case. We have our data

Table[f[n, 2, a, b, c], {n, 2, 10}]

and we make a guess -careful with the shifts in the FindSequenceFunction command

FindSequenceFunction[{1, 1/2, 1/3, 1/4, 1/5}, n] /. n -> n - 1
FindSequenceFunction[{2, 1, 2/3, 1/2, 2/5, 1/3, 2/7, 1/4, 2/9}, n] /. 
 n -> n - 1
FindSequenceFunction[{1/2, 1/6, 1/12, 1/20, 1/30, 1/42, 1/56, 1/72, 
   1/90}, n] /. n -> n - 1

We write our conjectured formula

guess2[n_, a_, b_, c_] := 
 1/2 a^4 (1 + 2 b + b^2/2) Exp[b + c] + 
  a^2 (1 + b) (1 + c/(n - 1)) Exp[b + c] + (1/
   2) (1 + (2 c)/(n - 1) + c^2/(n (n - 1))) Exp[b + c] 

and as before we test our result non-trivially by running

Table[f[n, 2, a, b, c] - guess2[n, a, b, c], {n, 2, 21}]

From the above we get

{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}

as we should.

Once, we have enough analytic formulae in n we can try to spot the general pattern; i.e guess a formula in terms of n1 that produces all the previous analytic results. Once we have that, we verify against a couple of non-trivial results -values for n and n1- that have not been used in order to do our guesswork.

Now we are done and happy.

$\endgroup$
8
  • 1
    $\begingroup$ Very good. Because you've noticed that all combinations of $n>=n'$ have the multiplicative term Exp[b + c], the following would seem to give a strong hint as to the overall pattern: Do[Print[TableForm[Table[{n, n1, f[n, n1, a, b, c] /. Exp[b + c] -> 1}, {n, n1, 9 + n1}], TableHeadings -> {None, {"n", "n1", "Result"}}]], {n1, 0, 5}]. $\endgroup$
    – JimB
    Feb 2, 2022 at 17:17
  • $\begingroup$ Precisely. That's how I would go about it, it's just a bit arduous for me to finish off this computation fully right now. But it's pretty obvious that there is indeed a pattern and one should be able to get a closed formula in terms of n and n1. $\endgroup$
    – user49048
    Feb 2, 2022 at 17:50
  • $\begingroup$ Same here. Just not enough time in the day. Also, the definition of $g(x,x')$ is essential as it must drop to zero very quickly. So in the end it's probably putting a limit on the maximum values of $n$ and $n'$ that will be necessary. And I learned something new from your answer: I wrongly assumed that 'FindSequenceFunction` only worked on integers. Thanks! $\endgroup$
    – JimB
    Feb 2, 2022 at 18:41
  • 1
    $\begingroup$ @DiSp0sablE_H3r0 By analyzing the patterns, I was finally able to obtain the closed-form expression in terms of $n$ and $n1$ that I was looking for. Here is the expression: $F(n, n1, a, b, c)=\sum_{p=0}^{n1}\sum_{q=0}^{n1}\sum_{r=0}^{n1} \frac{e^{b+c} b^q c^r (n-\text{n1})! a^{2 (\text{n1}-p)}}{(q!)^2 r! (p-r)! (n-\text{n1}+r)! (\text{n1}-p-q)!}$ Here's the code: Sum[(a^(2 (n1 - p)) b^q c^r E^(b + c) (n - n1)!)/((n1 - p - q)! (q!)^2 (p - r)! r! (n - n1 + r)!), {p, 0, n1}, {q, 0, n1}, {r, 0, n1}] $\endgroup$
    – JayanthJ
    Feb 11, 2022 at 12:08
  • 1
    $\begingroup$ Perfect!!! Great job. Good to know that eventually the method worked $\endgroup$
    – user49048
    Feb 11, 2022 at 14:58

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.