Creating 28$\times$28 matrix whose entries are Levi Civita tensors

Question

I would like to create a particular 28$\times$ 28 matrix whose entries are given by

$$ X_{[ij][kl]} = \delta^{[ij][kl]}_{1234} + \delta^{[ij][kl]}_{5678}$$

where $\delta^{ijkl}_{abcd} = \begin{cases} +1 & \text{if $ijkl$ is an even permutation of $abcd$}\\ -1 & \text{if $ijkl$ is an odd permutation of $abcd$} \\0 & \text{otherwise}\end{cases}$

There are several tricky features about this matrix, making it hard to be implemented in Mathematica.

1. The entries of $X$ are labeled by antisymmetric pairs $[ij]$ where $i,j$ (individually) run from 1 to 8, but when they are combined in antisymmetric pairs, there are 28 combinations (here organised into 7 blocks, each 4$\times$ 4): (12, 34, 56, 78); (13, 24, 57, 68); (14, 23, 58, 67); (15, 26, 37, 48); (16, 25, 38, 47); (17, 28, 35, 46); (18, 27, 36, 45)
2. So basically, X is of block-diagonal form, with 7 blocks with entries labeled as above. So to calculate the entries, one uses 4-dimensional Levi-civita tensors for each entry. The only way I know to create this 28$\times$28 matrix would be to enter each entry individually using the Signature[{i,j,k,l}] function. This would repeat for the rest of the 6 remaining diagonal blocks (all entries corresponding to elements of different blocks vanish), and it is rather tedious.

So I'd be very grateful if someone could come up with a smart way to do this ?

Answer 1

Is this what you are looking for?

n = 8;
idx = Flatten[Table[{i, j}, {i, 1, n}, {j, i + 1, n}], 1];
list1 = Range[1, 4];
list2 = Range[5, 8];

A = Table[
   With[
    {c = Join[a, b]},
    With[
      {d = Sort[c]},
      Signature[c] (Boole[d == list1] + Boole[d == list2])
      ]
    ],
   {a, idx}, {b, idx}];

Answer 2

If you have M9+, you could use SymmetrizedArray to create an $8 \times 8 \times 8\times8$ dimensional array with the desired symmetry:

X = SymmetrizedArray[
    {{1,2,3,4}->1, {5,6,7,8}->1},
    {8,8,8,8},
    Antisymmetric[{1,2,3,4}]
];

To convert this to a $28\times28$ matrix, you would group the first 2 and last 2 dimensions:

Y = Flatten[X, {{1,2}, {3,4}}];

and then extract the upper right indices:

upperRight = Pick[
    Range[64],
    Flatten @ LowerTriangularize[ConstantArray[1, {8,8}]],
    0
]

{2, 3, 4, 5, 6, 7, 8, 11, 12, 13, 14, 15, 16, 20, 21, 22, 23, 24, 29, 30, 31, 32, 38, 39, 40, 47, 48, 56}

to arrive at:

Z = Y[[upperRight, upperRight]];

This is the same as @Henrik's answer:

A == Z

True