Find the solid and it´s volume formed by the intersection of two surfaces

Question

I am trying to plot the solid formed by the intersection of the surface between

p1 = Plot3D[1 + x^2 - y^2, {x, -1.2, 1.2}, {y, -1.2, 1.2}] 

and

p2 = Plot3D[3 Log[1 + x^2], {x, -1.4, 1.4}, {y, -1, 1}]

I am also trying to get the volume of said solid. I've tried the solution given in How to plot and find the volume of a solid?, but I am only recently starting in this language and can't manage to adapt it to work with my functions. Any help will be apreciated. Thank you.

Here is the code for the two surfaces and its intersection.

Answer 1

Clearly the maximum x extent will be when y==0. Use Reduce to find the x extent.

Reduce[1+x^2-0^2==3 Log[1+x^2],x]

Use Reduce to find the y extent for a given x.

Reduce[1+x^2-y^2==3 Log[1+x^2],y]

Then Integrate over the y extent for each x to find the volume.

NIntegrate[1+x^2-y^2-3 Log[1+x^2],
   {x,-Sqrt[E^(-ProductLog[-1/3])-1],Sqrt[E^(-ProductLog[-1/3])-1]},
   {y,-Sqrt[1+x^2-3*Log[1+x^2]],Sqrt[1+x^2-3*Log[1+x^2]]}]

In exactly the same way Plot3D the volume between them.

Plot3D[{1+x^2-y^2,3 Log[1+x^2]},
{x,-Sqrt[E^(-ProductLog[-1/3])-1],Sqrt[E^(-ProductLog[-1/3])-1]},
{y,-Sqrt[1+x^2-3*Log[1+x^2]],Sqrt[1+x^2-3*Log[1+x^2]]}]

Check all this very carefully to make certain no mistakes have been made.

Answer 2

A different way to discretize is to work with each surface separately and take their intersection.

ToBMR[g_Graphics3D] := With[{s = DiscretizeGraphics[g]},
  BoundaryMeshRegion[MeshCoordinates[s], MeshCells[s, 2]]
];

p1 = Plot3D[1 + x^2 - y^2, {x, -1.5, 1.5}, {y, -1.5, 1.5}, 
  Filling -> Bottom, PlotRange -> {-2, Automatic}, PlotPoints -> 50];

p2 = Plot3D[3 Log[1 + x^2], {x, -1.5, 1.5}, {y, -1.5, 1.5}, 
  PlotStyle -> Red, Filling -> Top, PlotPoints -> 50];

m1 = ToBMR[p1];
m2 = ToBMR[p2];

saddle = RegionIntersection[m1, m2]

Volume[saddle]

1.24449

---

Here's the same calculation with PlotPoints -> 200:

Volume[saddle]

1.24697

Answer 3

per comment:

r = ImplicitRegion[
   3 Log[1 + x^2] < z < 
        1 + x^2 - y^2, {{x, -1.4, 1.4},y,z}];
Volume[r]

1.2471664022353517

DiscretizRegion and RegionPlot have a hard time with it though.

DiscretizeRegion[r, MaxCellMeasure -> .0001, MeshQualityGoal -> 1]

This does not work at all in v10.1 by the way.

Edit. Another way to get the figure:

Plot3D[{1 + x^2 - y^2, 3 Log[1 + x^2]}, {x, -1, 1}, {y, -1, 1},
 RegionFunction -> Function[{x, y}, 3 Log[1 + x^2] <= 1 + x^2 - y^2]]

and another volume:

NIntegrate[
 Boole[3 Log[1 + x^2] <= z <= 1 + x^2 - y^2], {x, -1, 1}, {y, -1, 
  1}, {z, -1, 3}]

1.247166402235352