Given two lists of unequal length:
ind = Range[0, 4];
color = {"red", "green", "blue", "black"};
how can I produce efficiently the following list which is as long as the shorter of the two?
{{"red", 0}, {"green", 1}, {"blue", 2}, {"black", 3}}
$\begingroup$
$\endgroup$
5
6 Answers
$\begingroup$
$\endgroup$
1
Some ideas:
Partition[Riffle[color, ind, {2, -1, 2}], 2]
Flatten[{color, ind}, {2}] // Cases[{_, _}]
{color, PadRight[ind, Length@color]}\[Transpose]
ind ~Riffle~ color ~Partition~ 2 ~Reverse~ 2
MapIndexed[{#, Extract[ind, #2]} &, color]
Take[#, All, Min[Length /@ #]]\[Transpose] &[{color, ind}]
All produce:
{{"red", 0}, {"green", 1}, {"blue", 2}, {"black", 3}}
I'll note that the last method, which was perhaps my most serious attempt to answer this pragmatically, can be applied to any number of lists:
fn = Take[#, All, Min[Length /@ #]]\[Transpose] &;
fn[{{1, 2, 3}, Alphabet[], 2^Range@5}]
{{1, "a", 2}, {2, "b", 4}, {3, "c", 8}}
answered Mar 5, 2017 at 2:03
-
$\begingroup$ You have once again lived up to your username. $\endgroup$ Commented Mar 5, 2017 at 20:59
$\begingroup$
$\endgroup$
5
Here is a function to do it for any two lists. It doesn't care about the order in which the lists appear as arguments.
makePairs[a_List, b_List] :=
Transpose[Take[#, Min[{Length @ a, Length @ b}]] & /@ {a, b}]
makePairs[color, ind]
{{"red", 0}, {"green", 1}, {"blue", 2}, {"black", 3}}
makePairs[ind, color]
{{"red", 0}, {"green", 1}, {"blue", 2}, {"black", 3}}
answered Mar 5, 2017 at 6:22
-
$\begingroup$ FWIW that's pretty similar to my last method:
Take[#, All, Min[Length /@ #]]\[Transpose] &$\endgroup$ Commented Mar 5, 2017 at 6:23 -
1$\begingroup$ @Mr.Wizard. The methods might be similar, but the programming philosophy illustrated by the two answer differ enough that I think this deserves to stand. $\endgroup$ Commented Mar 5, 2017 at 6:25
-
$\begingroup$ You mean you're not a fan of the shotgun answer? :^) $\endgroup$ Commented Mar 5, 2017 at 6:27
-
$\begingroup$ @Mr.Wizard. I like shotgun answers. I also think there should be room for other kinds. $\endgroup$ Commented Mar 5, 2017 at 6:35
-
$\begingroup$ No argument from me on that point! $\endgroup$ Commented Mar 5, 2017 at 6:55
$\begingroup$
$\endgroup$
Another variant:
DeleteCases[
Transpose[PadRight[{color, ind}, Automatic, Missing]], {___,
Missing, ___}]
$\begingroup$
$\endgroup$
Block[{i = 1}, {#, ind[[i++]]} & /@ color]
{{"red", 0}, {"green", 1}, {"blue", 2}, {"black", 3}}
$\begingroup$
$\endgroup$
n = Range[0, 4];
c = {"red", "green", "blue", "black"};
Using TransposeTableau by Ed Pegg Jr and Steven Skiena
TransposeTableau = ResourceFunction["TransposeTableau"];
Cases[{_, _}] @ TransposeTableau[{c, n}]
{{"red", 0}, {"green", 1}, {"blue", 2}, {"black", 3}}
Cases[{_, _}] @ TransposeTableau[{{1, 2}, c}
{{1, "red"}, {2, "green"}}
$\begingroup$
$\endgroup$
ind = Range[0, 4]; color = {"red", "green", "blue", "black"};
Using GeneralizedMapThread by Sander Huisman:
GeneralizedMapThread = ResourceFunction["GeneralizedMapThread"];
Diagonal[GeneralizedMapThread[List, {color, ind}, 2]]
{{"red", 0}, {"green", 1}, {"blue", 2}, {"black", 3}}
answered Jul 18 at 18:53
Transpose. $\endgroup$Transpose[{color, Take[ind, Length[color]]}. $\endgroup$zipfunction in Python. $\endgroup$