Integrate to calculate enclosed area

Question

I am trying to 'use an integral in polar coordinates to calculate the area enclosed by this curve':

The curve is: $r=\sin 2\theta$, $\theta \in [0, \pi]$ which I believe is already in polar form.

I plotted it as:

PolarPlot[Sin[2θ], {θ, 0, π}]

I have looked in several places at possible way to find area, but it seems that there's a ton of ways to do it. I have seen people talk about regions, booles, approximate areas, solve, etc...and have only found myself getting confused and jumbled up when I try to enter in my own problem.

There are two things I am looking to do with this curve. First is to find the area enclosed by the curve. Then I want to find the length of the curve. But, first things first, I am trying to figure out the area first.

I hope this is specific enough.

Thanks in advance for your help

Answer 1

Area

As described on this page, the area enclosed by a polar curve is given by

$$A = \int_\alpha^\beta \frac{r(\theta)^2}{2} \mathrm{d}\theta$$

In your case this is,

Integrate[Sin[2 θ]^2/2, {θ, 0, π}]
N@%
(* π/4 *)
(* 0.785398 *)

You can get this same answer using Region functionality by first making a RegionPlot, converting it to a MeshRegion and finding the area,

RegionPlot[{Sqrt[x^2 + y^2] <= Sin[2 ArcTan[y/x]], 
   Sqrt[x^2 + y^2] <= Sin[2 ArcTan[-y/x]]}, {x, 0, 1}, {y, -1, 1}, 
  PlotPoints -> 60] // DiscretizeGraphics

Area@%
(* 0.785374 *)

But this is only good to a limited degree of precision.

Arc Length

Going back to that same site, the formula for the arc length is

$$L = \int \mathrm{d}s$$

where

$$\mathrm{d}s = \sqrt{r(\theta)^2+\left(\frac{\mathrm{d}r(\theta)}{\mathrm{d}\theta}\right)^2}\mathrm{d}\theta$$

Using Integrate we get

Integrate[
 Sqrt[Sin[2 θ]^2 + D[Sin[2 θ], θ]^2], {θ, 
  0, π}]
N@%
(* 4 EllipticE[3/4] *)
(* 4.84422 *)

Or, we can extract the Line object from the PolarPlot and find its length using ArcLength

Cases[
   PolarPlot[Sin[2 θ], {θ, 0, π}, PlotRange -> All],
    Line[_], Infinity] // First // ArcLength
(* 4.8441 *)

Again, this seems to be good for three decimal places.

Answer 2

Here's a way with ParametricRegion:

With[{r = Sin[2θ]},
  Area[ParametricRegion[{t r Cos[θ], t r Sin[θ]}, {{t, 0, 1}, {θ, 0, π}}]]
]

π/4

---

Area also has a built in syntax for parameterized surfaces:

With[{r = Sin[2θ]},
  Area[{t r Cos[θ], t r Sin[θ]}, {t, 0, 1}, {θ, 0, π}]
]

π/4

---

We can explicitly tell Area to use polar coordinates and not have to do the coordinate system transform ourselves:

With[{r = Sin[2θ]},
  Area[{t r, θ}, {t, 0, 1}, {θ, 0, π}, "Polar"]
]

π/4

Here's arclength:

With[{r = Sin[2θ]}, 
  ArcLength[{r, θ}, {θ, 0, π}, "Polar"]
]

4 EllipticE[3/4]

And an approximation:

With[{r = Sin[2θ]}, 
  ArcLength[{r, θ}, {θ, 0, π}, "Polar", Method -> "NIntegrate"]
]

4.84422

Answer 3

Using Green's theorem (using in this case: 1/2{-y,x}):

c[t_] := {Sin[2 t] Cos[t], Sin[2 t] Sin[t]}
Integrate[1/2 ({-1, 1} c[t][[{2, 1}]]).c'[t], {t, 0 , Pi}]

yields $\pi/4$.

Arc length:

arclength = Integrate[Sqrt[c'[t].c'[t]], {t, 0, Pi}]

yields:4 EllipticE[3/4] (4.84422)