About Hue's period

Question

So we can see that Hue is a periodic function. Its period is 1. And the specifier from documentation. Sorry for I cannot cite my local language documentation. Let me take a look the normal situation:

Graphics @ {Hue[-0.33, 1, 1], Disk[]}

But how about this?

Image[{{{-0.33, 1, 1}}}, ColorSpace -> "HSB"]

Update the question like this LLlAMnYP, we can see the data will not be adjust to 0~1:

Answer 1

So LLlAMnYP answered why it displays red instead of blue, but it got me to thinking how to make it behave the way OP expected it to.

Here is a comparison of Hue inside of Image and just by itself:

TableForm[
{Table[{n, Image[{{{n, 1, 1}}}, ColorSpace -> "HSB"],
 Graphics[{Hue[n, 1, 1], Rectangle[]}, ImageSize -> 22]}, {n, -2, 0, 0.1}], 
   Table[{n, Image[{{{n, 1, 1}}}, ColorSpace -> "HSB"], 
   Graphics[{Hue[n, 1, 1], Rectangle[]}, ImageSize -> 22]}, {n, 0, 2, 0.1}]}
   ]

So to get it to behave properly, we use Mod, with a slight offset so that it doesn't set a brightness value of 1 equal to 0:

TableForm[
 {Table[{n, Image[Mod[{{{n, 1, 1}}}, 1, .001], ColorSpace -> "HSB"],
     Graphics[{Hue[n, 1, 1], Rectangle[]}, ImageSize -> 22]}, {n, -2, 
    0, 0.1}], 
     Table[{n, 
    Image[Mod[{{{n, 1, 1}}}, 1, .001], ColorSpace -> "HSB"], 
       Graphics[{Hue[n, 1, 1], Rectangle[]}, ImageSize -> 22]}, {n, 
    0, 2, 0.1}]}
    ]

and your original example is simply

Image[Mod[{{{-0.33, 1, 1}}}, 1, .001], ColorSpace -> "HSB"]

Answer 2

Hue is a periodic function. However, from the documentation:

Image[data,"type"] coerces values in data to the specified type by rounding or clipping.

So as argument to image, negative hues are equivalent to 0.

Re: comment by Jason B.
This is even more explicitly explained in two nearby lines of the documentation:

Image[data] is equivalent to Image[data,"Real"].
Image[data] by default allows any real number, but displays only values between 0 and 1.

@Yode notes, that the ImageData itself is not clipped to 0-1. At first glance, this doesn't matter, as clipped or not, the output result will be the same. However, consider

{im1, im2} = {Image[{{{-.5, .5, .5}}}, ColorSpace -> "HSB"],
                   Image[{{{0., .5, .5}}}, ColorSpace -> "HSB"]}

(* Identical appearance, differing ImageData *)

im3 = Image[{{{0., 1., 1.}}}, ColorSpace -> "HSB"]

{ImageSubtract[im3,im1], ImageSubtract[im3,im2]}

Thus we subtract from the same image images of identical appearance and get different results. I feel, it's not exactly desirable behavior.

Re: follow-up question in comment:

data = {{{-.33, 1., 1.}}}
Apply[{Mod[#1, 1], #2, #3} &, data, {2}]
Image[Apply[{Mod[#1, 1], #2, #3} &, data, {2}], ColorSpace -> "HSB"]

Here's a better approach using specialized image functions (ImageApply):

im1 = Image[data, ColorSpace -> "HSB"]
ImageApply[{Mod[First@#, 1]}~Join~Rest@# &, im1]