ArrayPlot - Question about ColorFunction and PlotLegends

Question

I have a noise image (8bit, gray scale): https://i.sstatic.net/RIgOk.png

The following code:

image = Import["https://i.sstatic.net/RIgOk.png", "PNG"];

imageData = N@ImageData[image, "Byte"];

colTable = {Red, Green, Blue};

plot = ArrayPlot[imageData, ColorFunction -> (Blend[colTable, #] &), 
  PlotLegends -> Automatic, FrameTicks -> All, ImageSize -> Medium]

produces an ArrayPlot:

I have two questions:

1. How can I change the vertical extension of the color legend, so that it as high as the plot is.

2. The image contains only Byte values of 9,10,11:

Histogram[Flatten@imageData, ScalingFunctions -> "Log", 
 ImageSize -> Medium]

How can I use my upper color table which only consist of 3 colors instead of smoothing in between?

Answer 1

A couple of ideas here. First, as J.M. commented above, you could use exact (Integer) values and ColorRules:

imageData = ImageData[image, "Byte"];

ArrayPlot[imageData
 , ColorRules  -> Thread[{9, 10, 11} -> colTable]
 , PlotLegends -> Automatic
 , FrameTicks  -> All
 , ImageSize   -> Medium
]

That handily solves your legend size issue as well, at least for this case.

If that is not what you want you could use a color function like colTable[[⌈3 #⌉]] & to select the color you want. The legend can easily be resized by hand (just click it and drag the corners of the orange frame that appears).

ArrayPlot[imageData
  , ColorFunction -> (colTable[[⌈3 #⌉]] &)
  , PlotLegends   -> Automatic
  , FrameTicks    -> All
  , ImageSize     -> Medium
]

---

Finally with rcollyer's assistance I learned that we need to specify an explicit AspectRatio to get correct autosizing of the legend in this case:

ArrayPlot[imageData
  , ColorFunction -> (colTable[[⌈3 #⌉]] &)
  , PlotLegends   -> Placed[Automatic, Right]
  , FrameTicks    -> All
  , ImageSize     -> Medium
  , AspectRatio   -> 1/3
]

Incorporating an additional detail from the comments, we can set the range of the legend bar like this:

ArrayPlot[imageData
  , ColorFunction -> (colTable[[⌈3 #⌉]] &)
  , PlotLegends   -> Placed[BarLegend[{Automatic, {9, 12}}], Right]
  , FrameTicks    -> All
  , ImageSize     -> Medium
  , AspectRatio   -> 1/3
]

Answer 2

Try this:

    plot = ArrayPlot[imageData, ColorFunction -> (Blend[colTable, #] &), 
  PlotLegends -> BarLegend[Automatic, 2, LegendMarkerSize -> 125], 
  FrameTicks -> All, ImageSize -> Medium]

with the effect:

or this:

     plot = ArrayPlot[imageData, ColorFunction -> (Blend[colTable, #] &), 
      PlotLegends ->Placed[BarLegend[Automatic, 2, LegendMarkerSize -> 340], Below], 
FrameTicks -> All, ImageSize -> Medium]

yielding the following

Have fun!

Answer 3

Personally, I think using ColorRules is the best option. But, in case you want to use ColorFunction (with the resulting BarLegend), I would suggest setting the AspectRatio, too, e.g.

ArrayPlot[imageData, ColorFunction -> (Blend[colTable, #] &), 
 PlotLegends -> Automatic, ImageSize -> Medium, FrameTicks -> All, 
 AspectRatio -> 1/2]

Or you could set it to 1

ArrayPlot[imageData, ColorFunction -> (Blend[colTable, #] &), 
 PlotLegends -> Automatic, ImageSize -> Medium, FrameTicks -> All, 
 AspectRatio -> 1]

Although, I prefer 1/2.