How to extract an association with similar keys from another association?

Question

Considering we have an association like:

asc1 =  <|"a.s.r"->1, "a.s.r345" -> 45, "asc" -> "cas", "qwrs" -> 78, "a.s.r[4]/vu" -> 4, "es" -> 74|>

How to extract an asc2 to include only the pairs where key starts with "a.s.r", as the following:

asc2 = <|"a.s.r"->1, "a.s.r345" -> 45, "a.s.r[4]/vu" -> 4|>

Thank you!

Mr.Wizard · Accepted Answer · 2015-07-23 21:03:18Z

6

asc1 // KeySelect[StringMatchQ[#, "a.s.r*"] &]

<|"a.s.r" -> 1, "a.s.r345" -> 45, "a.s.r[4]/vu" -> 4|>

Responding to the follow-up questions in the comments:

Count[Keys @ asc1, s_String /; StringMatchQ[s, "a.s.r*"]]

3

asc1 // KeySelect[! StringMatchQ[#, "a.s.r*"] &]

<|"asc" -> "cas", "qwrs" -> 78, "es" -> 74|>

Also:

GroupBy[Normal@asc1, StringMatchQ[First@#, "a.s.r*"] &, Association]

<|True -> <|"a.s.r" -> 1, "a.s.r345" -> 45, "a.s.r[4]/vu" -> 4|>, 
 False -> <|"asc" -> "cas", "qwrs" -> 78, "es" -> 74|>|>

Or to modify asc1 in-place:

asc1 ~KeyDropFrom~ Keys[asc2];

asc1

<|"asc" -> "cas", "qwrs" -> 78, "es" -> 74|>

answered Jul 23, 2015 at 20:45

Mr.Wizard

273k34 gold badges595 silver badges1.4k bronze badges

$\begingroup$ Thank you! Is there a way to check if I have more than 1 "a.s.r*" or any other key in my association? $\endgroup$
– SuTron
Commented Jul 23, 2015 at 20:49
$\begingroup$ And also how can I extract asc1 from asc, so that to have asc2 without asc1 $\endgroup$
– SuTron
Commented Jul 23, 2015 at 20:55
1

$\begingroup$ @SuTron See update. $\endgroup$
– Mr.Wizard
Commented Jul 23, 2015 at 21:06

Add a comment |

1 Answer 1