10
$\begingroup$

I want to find limit of infinite nested radical

$\quad \quad \sqrt{1+\sqrt[2!]{2^2+\sqrt[3!]{3^3+...}}}$

but I don't know how to define this expression in Mathematica. How can I define it and find the limit:

$\quad \quad \lim_{n \to\infty} \sqrt{1+\sqrt[2!]{2^2+\sqrt[3!]{3^3+...+\sqrt[n!]{n^n}}}}$

$\endgroup$
3
  • 2
    $\begingroup$ You can define this sequence in Mathematica with the Fold command: lista = Table[i, {i, 2, 4}]; (Sqrt[1 + Fold[Sqrt[#2^#2 + (#1)]^#2! &, x, Reverse[lista]]] /.x -> 0) Will yield the result for up to 4, putting in higher numbers quickly shows the function explodes to infinity. Not sure how to evaluate the limit, but it goes to infinity. $\endgroup$
    – Feyre
    Jul 2 '15 at 12:00
  • 5
    $\begingroup$ Your math is wrong. Your pure function should be (#2^#2 + #1)^(1/#2!) &, not Sqrt[#2^#2 + (#1)]^#2! &. It looks like the limit is 1.84307598466..., not infinity. $\endgroup$
    – Chip Hurst
    Jul 2 '15 at 13:03
  • 2
    $\begingroup$ The expression given in the question looks a bit funny to me. Why is it Sqrt[1 + ...] rather than 1 + (...)^(1/2!)? @ChipHurst's suggestion seems "nicer". Maybe you really want the square root of that result, but it could perhaps help to clarify this. $\endgroup$ Jul 2 '15 at 14:06
8
$\begingroup$

Here is an approach using FixedPoint, where I keep the output in exact form to see how many terms are needed to satisfy a given tolerance:

Clear[x];
step[{n_, f_}] := {n + 1, f /. x -> (n^n + x)^(1/n!)};
tolerance = $MachineEpsilon;
sum =
 Last@FixedPoint[step, {2, Sqrt[1 + x]}, 
    SameTest -> (tolerance > Abs[Last[#1] - Last[#2]] /. 
        x -> 0 &)] /. x -> 0

$$\sqrt{1+\sqrt{4+\sqrt[6]{27+\sqrt[24]{256+\sqrt[120]{31 25+\sqrt[720]{46656+\sqrt[720]{7}}}}}}}$$

N[sum, 16]

$1.843075984668544$

tolerance = 10^-40;
sum =
 Last@FixedPoint[step, {2, Sqrt[1 + x]}, 
    SameTest -> (tolerance > Abs[Last[#1] - Last[#2]] /. 
        x -> 0 &)] /. x -> 0

sqrts

In FixedPoint, the function step handles both the index n and the iterated root f. The dummy variable x is used to insert the next root.

$\endgroup$
0
9
$\begingroup$
EDIT : Corrected error.

Clear[list];

list[n_] := Range[n, 2, -1];

x = Sqrt[1 + Fold[HoldForm[(#2^#2 + #1)^(1/#2!)] &, 0, list[5]]]

enter image description here

x // Map[ReleaseHold, #, {0, Infinity}] & // N // InputForm

1.8430759846682

$\endgroup$
2
  • 1
    $\begingroup$ s[n_]:=Sqrt[1 + Fold[(#2^#2 + #1)^(1/#2!) &, 0, Range[n, 2, -1]]] $\endgroup$
    – chuy
    Jul 2 '15 at 14:06
  • $\begingroup$ @OleksandrR. - corrected my error. Thanks. $\endgroup$
    – Bob Hanlon
    Jul 2 '15 at 14:29
6
$\begingroup$
f[1, x] = (1 + x)^(1/2);
f[n_ /; n > 1, x] := f[n - 1, x] /. x :> (x + n^n)^(1/n!)

The above function can generate terms of the series. For example

$\quad \quad f(3,\,x)=\sqrt{1+\sqrt[2!]{2^2+\sqrt[3!]{3^3+x}}}$
$\quad \quad f(4,\,x)=\sqrt{1+\sqrt[2!]{2^2+\sqrt[3!]{3^3+\sqrt[4!]{4^4+x}}}}$

f can be used to study the convergence of the OP's series.

Table[NumberForm[N @ f[i, x] /. x -> 0, 16], {i, 7}]
{1.`, 1.7320508075688772`, 1.8423273788801293`, 1.8430758571923342`, 
 1.8430759846682`, 1.8430759846685443`, 1.8430759846685443`}

So with MachinePrecision, the sequence in question converges to 1.8430759846685443 with MachinePreision.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.