Optimizing an energy functional in mathematica using variational calculus

Question

I have an energy functional which I want to optimize using calculus of variation.

It would be nice if someone could please post a working example using mathematica. The procedure is as follows, specify the energy functional, compute the Euler-Lagrange equation, discretize them and if possible run for a sample data.

There are some links to the package for calculus of variation. But none of them is providing a complete example as I have described in the above paragraph.

UPDATE1

I am trying the simple Lucas-and-Kanade energy functional

$E(u(x_0,y_0),v(x_0,y_0)) = \int(f_x(x,y,t)u+f_y(x,y,t)v+f_t)dx dy$

I have tried to do it with [this link]

UPDATE2

The correct form of the energy functional is, courtesy of [rcollyer]

$E(u(x,y),v(x,y)) = \int(f_x(x,y,t)u+f_y(x,y,t)v+f_t)^2dx dy$

The question is now how to descritize the Euler-Lagrange equations. and solve it for some artificial data. (this is not extra thing specified in the question already)

* UPDATE3* the complete solution procedure is as follows:

The E-L equations for the integrand of the above energy functional are as follows and we set the first variation to zero

$2f_x(f_x(x,y,t)u+f_y(x,y,t)v+f_t)=0$

$2f_y(f_x(x,y,t)u+f_y(x,y,t)v+f_t)=0$

in the matrix form it will look as follows

Now we can simply solve for u and v because we have two equations and two unknowns but the derivatives are needed to be descritized. For example if we take the forward difference assuming the distance is 1

$f_x = f_{i+1}-f_{i}$

$f_y = f_{j+1}-f_{j}$

In above equations i and j represent the indexing in x and y direction respectively.

$f_t = f_{2}-f_{1}$

Here in the above equation the function is described by indices 1 and 2 describe the function in the temporal direction. (Mathematica provides a lot of variety for descritizing as per the documentation)

So the idea is to be able to replace the derivative with finite differences and we should be able to solve the equation system for u and v given the data.

thanks a lot

Answer 1

There is some suggestion in what literature I had access to that your integrand should be squared. Regardless, I think I have some advice for using the VariationalMethods` package. In order to make it work, I had to make $u$ and $v$ dependent on $x$ and $y$ despite the implication that they are independent of $x$ and $y$ on the RHS of your equation. Doing otherwise makes only one function available for differentiation: $f(x,y,t)$. The papers imply that it is really $u$ and $v$ that you are looking for, but taking the variational derivative of your integrand with respect to $f$, gives

VariationalD[D[f[x, y, t], x] u[x, y] + D[f[x, y, t], y] v[x, y] + D[f[x, y, t], t], f[x,y,t], {x,y,t}]
(* 0 *)

However, if you square the integrand you get

(* - 2*(Derivative[0, 0, 2][f][x, y, t]    + 2*v*Derivative[0, 1, 1][f][x, y, t] 
   + v^2*Derivative[0, 2, 0][f][x, y, t]   + 2*u*Derivative[1, 0, 1][f][x, y, t] 
   + 2*u*v*Derivative[1, 1, 0][f][x, y, t] + u^2*Derivative[2, 0, 0][f][x, y, t]) *)

This, however, differs quite considerably from your equation as it implies that there is an integral over $t$, also. This is indicated by the last term in VariationalD (and similarly in EulerEquations), but if you shorten it to only the spatial coordinates ({x,y}) you get the error

VariationalD::args: VariationalD takes a single integrand, 
   a function or list of functions, and a list of variables as input.

which is about the most useless error I have encountered. That said, that it generates an error makes sense as a functional is by definition a mapping from a function space to a number space, and by not integrating by $t$ you have a mapping between two function spaces. However, it works perfectly fine if you are concerned with $u(x,y)$ and $v(x,y)$ as they are not explicitly dependent on $t$ which of course implies that $E$ is dependent on $t$.

So, setting

integrand = D[f[x, y, t], x] u[x, y] + D[f[x, y, t], y] v[x, y] + D[f[x, y, t], t]

we get

VariationalD[integrand, {u[x, y], v[x, y]}, {x, y}]
(* {Derivative[1, 0, 0][f][x, y, t], Derivative[0, 1, 0][f][x, y, t]} *)

or

EulerEquations[integrand, {u[x, y], v[x, y]}, {x, y}]
(* {Derivative[1, 0, 0][f][x, y, t] == 0, Derivative[0, 1, 0][f][x, y, t] == 0} *)

If the integrand is supposed to be squared, then simply do this instead

VariationalD[integrand^2, {u[x, y], v[x, y]}, {x, y}]
(*
{  2*Derivative[1, 0, 0][f][x, y, t]
 * (Derivative[0, 0, 1][f][x, y, t] + v[x, y]*Derivative[0, 1, 0][f][x, y, t] 
    + u[x, y]*Derivative[1, 0, 0][f][x, y, t]
   ), 
   2*Derivative[0, 1, 0][f][x, y, t]
 * (Derivative[0, 0, 1][f][x, y, t] + v[x, y]*Derivative[0, 1, 0][f][x, y, t] 
    + u[x, y]*Derivative[1, 0, 0][f][x, y, t]
   )
 }
*)

(Note: Derivative[0, 1, 0][f][x, y, t] is the internal form an unevaluated derivative takes, and the above simply means $\partial f /\partial y$.)