10
$\begingroup$

We are asked to maximize and minimize $f(x,y)=4xy$, given the constraint $4x^2+y^2=8$, using the Lagrange Multiplier method. First, I enter the functions f and g.

f = 4 x*y;
g = 4 x^2 + y^2 - 8;

Then I solve using the Lagrange Multiplier method.

sols = Solve[{Grad[f, {x, y}] == λ Grad[g, {x, y}], 
   g == 8}, {x, y, λ}]

Which gives this output.

   {{x -> -1, y -> -2, λ -> 1}, {x -> -1, 
      y -> 2, λ -> -1}, {x -> 1, 
      y -> -2, λ -> -1}, {x -> 1, y -> 2, λ -> 1}}

I can then create the points to investigate.

{x, y} /. sols

Which gives this output.

{{-1, -2}, {-1, 2}, {1, -2}, {1, 2}}

Now I can evaluate f at each point.

f /. sols

Which gives this output.

{8, -8, -8, 8}

So, I have maximum values of 8 at the points $(-1,-2)$ and $(1,2)$, and minimum values of $-8$ at the points $(-2,2)$ and $(1,-2)$. Now, this can be visualized with the following image.

ContourPlot[f, {x, -2, 2}, {y, -3, 3},
 Contours -> Range[-10, 10],
 Mesh -> {{0}}, MeshFunctions -> Function[{x, y}, g],
 MeshStyle -> Directive[Thick, Yellow],
 Epilog -> {Red, PointSize[Large], Point[{x, y}] /. sols}]

function and extrema

Now, my question. I want to use the Lagrange multiplier technique to maximize $f(x,y,z)=xyz$ subject to the constraint $x^2+10y^2+z^2=5$.

f = x y z;
g = x^2 + 10 y^2 + z^2;
sols = Solve[{Grad[f, {x, y, z}] == λ Grad[g, {x, y, z}], 
    g == 5}, {x, y, z, λ}];
{x, y, z} /. sols

Gives the following output.

{{0, 0, -Sqrt[5]}, {0, 0, Sqrt[5]}, {0, -(1/Sqrt[2]), 0}, {0, 1/Sqrt[
  2], 0}, {-Sqrt[(5/3)], -(1/Sqrt[6]), -Sqrt[(5/3)]}, {-Sqrt[(5/
   3)], -(1/Sqrt[6]), Sqrt[5/3]}, {-Sqrt[(5/3)], 1/Sqrt[
  6], -Sqrt[(5/3)]}, {-Sqrt[(5/3)], 1/Sqrt[6], Sqrt[5/3]}, {Sqrt[5/
  3], -(1/Sqrt[6]), -Sqrt[(5/3)]}, {Sqrt[5/3], -(1/Sqrt[6]), Sqrt[5/
  3]}, {Sqrt[5/3], 1/Sqrt[6], -Sqrt[(5/3)]}, {Sqrt[5/3], 1/Sqrt[6], 
  Sqrt[5/3]}, {-Sqrt[5], 0, 0}, {Sqrt[5], 0, 0}}

And we can evaluate f at each of these points.

f /. sols

{0, 0, 0, 0, -(5/(3 Sqrt[6])), 5/(3 Sqrt[6]), 5/(
 3 Sqrt[6]), -(5/(3 Sqrt[6])), 5/(
 3 Sqrt[6]), -(5/(3 Sqrt[6])), -(5/(3 Sqrt[6])), 5/(3 Sqrt[6]), 0, 0}

So it appears that I have a maximum value of $\dfrac{5}{3\sqrt6}$ at four separate points and a minimum value of $-\dfrac{5}{3\sqrt6}$ at four separate points.

So, it appears I can do this part. The part I need help with is the image. Is it possible to produce contour surfaces of f and show where the constraint $g(x,y,z)=5$ touches a level surface of f at the minimum and maximum points?

Or, one image that shows touches at the maximum points and a second image that shows touches at the minimum points?

$\endgroup$
  • 1
    $\begingroup$ Maybe use ContourPlot3D with suitable z range spec, and likewise add z to the MeshFunctions setting. $\endgroup$ – Daniel Lichtblau Mar 27 '15 at 16:38
  • 1
    $\begingroup$ Related answer $\endgroup$ – garej Feb 21 '16 at 10:16
16
$\begingroup$

Here is a visualization using MeshFunctions (as mentioned by Daniel in the comment):

f = x y z;
g = x^2 + 10 y^2 + z^2;

gp = With[{r = 3},
   RegionPlot3D[g < 5, {x, -r, r}, {y, -r, r}, {z, -r, r}, 
    PlotStyle -> Orange, PlotPoints -> 40, Mesh -> None, 
    ViewPoint -> Front, PlotTheme -> "Classic"]
   ];

With[{r = 3}, Manipulate[
  Show[gp,
   ContourPlot3D[x y z == n, {x, -r, r}, {y, -r, r}, {z, -r, r}, 
    PlotPoints -> 40,
    Mesh -> {{5}},
    MeshFunctions -> Function[{x, y, z}, g],
    MeshStyle -> {Thick, Blue},
    ContourStyle -> Opacity[.5], PlotTheme -> "Classic"], PlotLabel -> Row[{"x y z = ", n}]],
  {n, 0.5, 1}]]

manipulate

I did it as a Manipulate so you can show the intersection using time as the additional variable that isolates the solution when the blue circle degenerates to a point. In principle one could also replace this by a Table of surfaces for different values of n in x y z == n, all displayed together with Show. You could also adjust the ViewPoint to your liking, to exhibit the shape of the contour for g from a different perspective.

$\endgroup$
  • $\begingroup$ Fantastic answer! This will be quite helpful for our students. $\endgroup$ – David Mar 27 '15 at 18:24

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.