Dynamic updating of Slot number [duplicate]

Question

I want to change the slot number inside Manipulate[]. Here is a minimal example which does not work:

Manipulate[Sin[#n] & [0, Pi/2], {n, Range[2]}]

I expect an output of 0 when n=1 and 1 when n=2 (sine evaluated at n-th argument).

I've also tried Slot[n], # n but they do not work either. I couldn't find any similar question.

How would you make it?

EDIT 1

Kuba's answer

Manipulate[Evaluate@Sin[Slot[n]] &[0, Pi/2], {{n, 1}, Range[2]}]

works for the minimal example. In my case i use it while plotting graphics:

Manipulate[
 Module[{min, max, col},
  {min, max} = Through@{Min, Max}@pointslf[1][[All, n]];
  col = {"TemperatureMap", {min, max}};
  Graphics3D[{ColorData[col][#6], PointSize[Large], 
      Point[{#1, #2, #3}]} & @@@ pointslf[1]]
  ],
 {n, Range[6, 7]}
 ]

If i substitute #6 with Evaluate@Slot[n] it doesn't work anymore. pointslf[1] is a matrix with coordinates (first three columns) and other stuff (next columns) i use to define the color.

How should i do it in this case?

Answer 1

You can do this:

Manipulate[Evaluate@Sin[Slot[n]] &[0, Pi/2], {{n, 1}, Range[2]}]

but I don't think it is as handy as:

Manipulate[Sin[{0, Pi/2}[[n]]], {{n, 1}, Range[2]}]

Answer 2

A simple workaround is to use Part and SlotSequence like this:

ColorData[col][{##}[[n]]]

Another workaround is to generate the function that is applied (@@@) with another function:

pointslf[1] = RandomReal[1, {12, 7}];

Manipulate[DynamicModule[{min, max, col, fn},
  {min, max} = Through@{Min, Max}@pointslf[1][[All, n]];
  col = {"TemperatureMap", {min, max}};
  fn[n_] := {ColorData[col][Slot[n]], PointSize[Large], Point[{#1, #2, #3}]} &;
  Graphics3D[fn[n] @@@ pointslf[1]]],
  {n, Range[6, 7]}
]

This is essentally the same as Kuba's method, merely presented in a different style.
Yet another way to write the same thing:

Graphics3D[With[{n = n}, {ColorData[col][Slot[n]], PointSize[Large], 
     Point[{#1, #2, #3}]} &] @@@ pointslf[1]]

The specific method is not important but rather the evaluation that it achieves. The body of a Function is not evaluated due to Function having the HoldAll attribute. We need to inject the value of n into this body to achieve what you want. In this particular case you can evaluate the entire function body with Evaluate, but in other cases you would not want to do that as unwanted evaluation would occur.

Regarding Evaluate see Explicit use of Evaluate not behaving the way I expect it to