Vertex styling in CommunityGraphPlot

Question

Is there a way to change the colours of nodes within one community? Mathematica assigns vertex colours automatically to each community. However, I'd rather like to use my own colour set.

CommunityGraphPlot[ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}]]

Answer 1

 g = CommunityGraphPlot[
 ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}]];

One method is to find the color set ,and then build a mapping, and replace the color by your own colorset.

colorList = Cases[g, Style[x__, color__] :> color, \[Infinity]] // Union;

rules = Thread[colorList -> {Red, Green, Blue, Yellow}];

g /. rules

Answer 2

I'd prefer the method in @halmir's answer, but using Style wrapper on the second argument of CommunityGraphPlot does not work in Version 9.0.1.0 (Windows 8 64bit). An alternative is to use VertexStyle with some pre-processing:

ClearAll[cgpF];
cgpF[g_Graph, coms_: Automatic, 
   cols_: GraphComputation`GraphInformationDump`$AutomaticColorList, 
   opts : OptionsPattern[CommunityGraphPlot]] :=
  Module[{gc = If[coms === Automatic, FindGraphCommunities[g], coms],vs, t},
   t = Thread[{gc, PadRight[cols, Length@gc, cols]}];
   vs = Join @@ (Function[{v, c}, # -> c & /@ v] @@@ t);
   CommunityGraphPlot[g, gc, VertexStyle -> vs, opts]];

Examples:

g1 = ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}];
cgpF[g1]

cgpF[g1, Automatic, cl = ColorData[43, "ColorList"], VertexSize -> 1,
 CommunityRegionStyle -> (Directive[EdgeForm[{Thickness[.01], Lighter[#, .4]}],
      Lighter[#, .7]] & /@ cl)]

randomcommunities = Internal`PartitionRagged[VertexList[g1],
   RandomChoice[IntegerPartitions[VertexCount[g1], {4}]]];
cgpF[g1, randomcommunities, cl = {Red, Cyan, Orange, Green}, VertexSize -> 1.5, 
 CommunityRegionStyle -> (Directive[{EdgeForm[{Thickness[.01], Lighter[#, .4]}],
       Opacity[.2], #}] & /@ cl)]

Answer 3

You could find community first and use Style wrapper over it:

comm = FindGraphCommunities[g];

color = ColorData[22, "ColorList"];

CommunityGraphPlot[g, Thread[Style[comm, color[[;; Length[comm]]]]]]

Answer 4

I appreciate other solutions. However, one can find that CommunityGraphPlot uses HighlightGraph to highlight communities. By default, HighlightGraph uses colors from GraphComputation`GraphInformationDump`defaultGroupColorFunction. So one can redefine it

ClearAll[GraphComputation`GraphInformationDump`defaultGroupColorFunction];
GraphComputation`GraphInformationDump`defaultGroupColorFunction[n_] :=
  ColorData[22, "ColorFunction"] /@ Range@n

CommunityGraphPlot[ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}]]

P.S. It is totally undocumented just-for-fun solution. defaultGroupColorFunction should be redefined after first evaluation of any Graph command.