Manipulate: How to create custom reset Button automatically?

Question

I have a complex Manipulate with more than 10 controls. Each one has its own default value.

I'd like to add a custom button in the control area to reset all control's values to their default values.

That's exactly what the "Initial Settings" in the Manipulate menu (+ on the up left corner) does. But I'd like to bring this action to a custom button located near my custom play/pause buttons.

I've searched the forum and I've read that "Initial settings" is a sort of bookmark, created automatically (?).

Yet I can't find how to execute this option from a custom button (or call that sort of automatic bookmark from a different control).

I've found many posts about setting the bookmarks programmatically, but no answer on the simpler question about how to invoke the "Initial settings" option from outside the manipulate menu.

I know that I could assign all the default values one by one (within the custom button) but that seems silly to me since there's already a similar option in the + menu.

Any suggestion?

Answer 1

Less ambitious:

addbutton[manipulate_] := 
 With[{box = ToBoxes@manipulate}, 
  With[{proc = Cases[box, HoldPattern["Variables" :> _], ∞]}, 
   With[{button = Button["Reset", CompoundExpression["Variables"] /. proc]}, 

    Composition[ToExpression, BoxData][
     box /. {("Body" :> x_) :> "Body" :> Column[{button, x}]}]]]]

addbutton@Manipulate[Dynamic[x], {x, 0, 1}]

CDFDeploy[ToFileName[{$TemporaryDirectory}, "Manipulate.cdf"], %]

---

More ambitious but:

As Jinxed has noticed, it fails when deployed to CDF with Export or CDFDeploy. However it works by File \ CDF export menu.

The reason is that it produces structure which is not quite correct, enough to work instantly in FE though.

addbutton[manipulate_] := With[{box = ToBoxes @ manipulate},
  With[{
    proc = Cases[box, HoldPattern["Variables" :> _], ∞]        
    },       
   With[{
     button = Button["Reset", CompoundExpression["Variables"] /. proc]
     },        
    Composition[ CellPrint, Cell[#, "Output"] &, BoxData
      ][
     box /. {
      ("Specifications" :> {x__}) :> "Specifications" :> {x, button},
      HoldPattern[Typeset`specs$$ = {y__}] :> (Typeset`specs$$ = {y, {Hold[button], 
        Manipulate`Dump`ThisIsNotAControl}})
      }
     ]
    ]
   ]]

---

addbutton[
 Manipulate[ Plot[Sin[a x + b], {x, 0, 6}], 
             {{a, 2, "Multiplier"}, 1, 4}, 
             {{b, 0, "Phase Parameter"}, 0, 10}]]

Answer 2

Not completely tested, based on undocumented structure of the DynamicModule constructed by Manipulate -- but it works for now:

Manipulate[a + b + c,
 {{a, 1}, 0, 5}, {{b, 2}, 0, 5}, {c, 0, 5},
 Button["Reset",
  Replace[
   Typeset`specs,
   {{{Hold[var_Symbol], val_}, ___} :> (var = val),
     {Hold[var_Symbol], val_, ___} :> (var = val)},
   1]]
 ]

Update. A combination of Kuba's and my ideas: We construct the code for the button from the code for the Manipulate. More likely not to break in future versions.

SetAttributes[addreset, HoldAll];
addreset[Manipulate[body_, specs___]] :=
 With[{btn = Button["Reset", CompoundExpression @@ #] &@Replace[
      Hold[specs],
      {{{var_Symbol, val_}, ___} :> (var = val),
       {var_Symbol, val_, ___} :> (var = val),
       _ -> Sequence[]},
      1]},
  Manipulate[body, specs, btn]
  ]

addreset@Manipulate[a + b + c,
  {{a, 1}, 0, 5}, {{b, 2}, 0, 5}, {c, 0, 5}
  ]

Answer 3

If you are not insisting on calling the Manipulate-menu's bookmark, the following approach might do the job:

Manipulate[Column[{Plot[TriangleWave[a x], {x, 0, 1}],
 Button["Custom Reset",
        (* first go back within the notebook *)
        SelectionMove[EvaluationNotebook[], Previous, Cell];
        SelectionMove[EvaluationNotebook[], Previous, Cell];
        (* then reevaluate the Manipulate[]-expression *)
        SelectionEvaluate[EvaluationNotebook[]];]
 }],{{a, 2}, 1, 10}]

However: This approach does not work with Computable Documents.