5
$\begingroup$

How can I prevent Mathematica from simplifying fractions? What I would like to do is run a test on a list of fractions to see how many are in their reduced form.

For example, I have a list:

1/10, 2/10, 5/10

I do not want Mathematica to treat it as:

1/10, 1/5, 1/2

I would like it left exactly as it was originally entered for comparison, i.e. if one list contains 2/10 and the other list contains 1/5 they should be treated as different elements.

I tried converting the elements to strings but Mathematica still simplified the fractions...

What is the best way to maintain the entire list in the original form?

Something like:

a = {1/10, 2/10, 3/10, 4/10, 5/10};
Internal`RationalNoReduce[Numerator[a], Denominator[a]]

still gives

Internal`RationalNoReduce[{1, 1, 3, 2, 1}, {10, 5, 10, 5, 2}]
Improve this question
$\endgroup$
4
  • $\begingroup$ Related: mathematica.stackexchange.com/questions/69655/… $\endgroup$
    – Michael E2
    Commented Jan 10, 2015 at 23:51
  • 2
    $\begingroup$ See my answer here. $\endgroup$
    – Greg Hurst
    Commented Jan 11, 2015 at 2:57
  • $\begingroup$ please see edit $\endgroup$
    – Raksha
    Commented Jan 11, 2015 at 18:05
  • $\begingroup$ I reopened the question and posted an answer addressing your stated goal. Your focus on "an entire list" makes me wonder if you are importing a list of fractions; if this is the case it will be important to import them in a held form, and you will need to describe the external format in your question. $\endgroup$
    – Mr.Wizard
    Commented Jan 11, 2015 at 19:23

2 Answers 2

Reset to default
4
$\begingroup$

Your expression will be evaluated unless it is entered in a held form, or a form that natively does not evaluate. For example:

a = Hold[1/10, 2/10, 3/10, 4/10, 5/10];

b = {{1,10}, {2,10}, {3,10}, {4,10}, {5,10}};

The second representation is a bit easier to work with as the first, which while not evaluating is nevertheless parsed differently from what you might expect:

a // FullForm

Hold[Times[1, Power[10, -1]], Times[2, Power[10, -1]], Times[3, Power[10, -1]], 
 Times[4, Power[10, -1]], Times[5, Power[10, -1]]]

Note that every fraction is not parsed as Rational but as Times and Power.

You can work with either format however. First the easy example (ref: Apply):

GCD @@@ b

{1, 2, 1, 2, 5}

A GCD of one means that the fraction is in reduced form, while any other value means it is not. You could for example Select the fractions that are or are not in reduced form:

Select[b, 1 == GCD @@ # &]

{{1, 10}, {3, 10}}

To work with the first format you could convert it to the second format with:

List @@ (a /. n_*(d_^-1) :> {n, d})

{{1, 10}, {2, 10}, {3, 10}, {4, 10}, {5, 10}}
Improve this answer
$\endgroup$
2
  • $\begingroup$ i think this is what I was looking for, thanks! :D $\endgroup$
    – Raksha
    Commented Jan 11, 2015 at 19:42
  • $\begingroup$ @Solarmew Glad I could help. :-) By the way including in a question what you are actually trying to accomplish is a good idea and in this case necessary to distinguish it from prior questions. $\endgroup$
    – Mr.Wizard
    Commented Jan 11, 2015 at 19:47
5
$\begingroup$

Use HoldForm

HoldForm[2/10]

$\frac{2}{10}$

ReleaseHold[%]

(* Out[68]= 1/5 *)
Improve this answer
$\endgroup$
2
  • $\begingroup$ Tyilo, but that only works for each element. Is there a way to apply it to the entire list without loops? $\endgroup$
    – Raksha
    Commented Jan 11, 2015 at 4:07
  • $\begingroup$ @Solarmew yes, the way is to apply HoldForm to the entire list HoldForm[{1/10, 2/10, 5/10}] $\endgroup$
    – user484
    Commented Jan 11, 2015 at 5:28

Not the answer you're looking for? Browse other questions tagged or ask your own question.