Undocumented form for FilledCurve[]

Question

New in Mathematica 8 is FilledCurve (and its cousin JoinedCurve). The docs state that this function can take a list of segments or components, each in the form of a Line, a BezierCurve, or a BSplineCurve. But the examples show alteration of a glyph, with a resulting JoinedCurve that has a different pattern. Here is a simplified example:

ImportString[ExportString[
    Style["\[FilledCircle]", Bold, FontFamily -> "Helvetica", FontSize -> 12],
    "PDF"],"TextMode" -> "Outlines"][[1, 1, 2, 1, 1]]

gives

FilledCurve[{{{1, 4, 3}, {1, 3, 3}, {1, 3, 3}, {1, 3, 3}}}, 
  {{{10.9614, 7.40213}, {10.9614, 10.2686}, {8.51663, 12.3137}, 
   {5.79394, 12.3137}, {3.05663, 12.3137}, {0.641063, 10.2686}, 
   {0.641063, 7.40213}, {0.641063, 4.53319}, {3.05663, 2.48813}, 
   {5.79394, 2.48813}, {8.53125, 2.48813}, {10.9614, 4.51856}, 
   {10.9614, 7.40213}}}]

The second argument is a list of points representing the glyph. The first list is some representation of smoothing the boundary given by the second list. For example, displaying the points alone as connected line segments

Graphics@Line[ImportString[ExportString[
 Style["\[FilledCircle]", Bold, FontFamily -> "Helvetica", 
  FontSize -> 12], "PDF"], "TextMode" -> "Outlines"][[1, 1, 2, 1, 1, 2, 1]]]

gives

Compare that with the JoinedCurve version:

Graphics[ImportString[
  ExportString[Style["\[FilledCircle]", Bold, FontFamily -> "Helvetica", 
    FontSize -> 12], "PDF"], "TextMode" -> "Outlines"][[1, 1, 2, 1, 1]]
  /. FilledCurve[a__] :> JoinedCurve[a]]

1. What exactly do the triples in the first list represent?
2. How can I reconstruct the smooth circle using other Graphics primitives, such as BSplineCurve?

My motivation is to be able to extract the curves from 2D glyphs and plot them in Graphics3D[] (e.g., with the replacement {x_Real,y_Real}:>{Cos[theta]x,Sin[theta]x,y}), since FilledCurve[] only works with Graphics[].

Answer 1

The first element in the triples seems to indicate the type of curve used for the segment where 0 indicates a Line, 1 a BezierCurve, and 3 a BSplineCurve. I haven't figured out yet what 2 does.

Edit: When the first element of the triple is 2, the segment will be a BezierCurve similar to option 1 except that with option 2, an extra control point is added to the list to make sure that the current segment is tangential to the previous segment.

The second digit indicates how many points to use for the segment, and the last digit the SplineDegree. To convert the FilledCurve to a list of Graphics primitives, you could therefore do something like

conversion[curve_] :=
   Module[{ff},

       ff[i_, pts_, deg_] :=
           Switch[i,
               0, Line[Rest[pts]],
               1, BezierCurve[Rest[pts], SplineDegree -> deg],
               2, BezierCurve[
                   Join[{pts[[2]], 2 pts[[2]] - pts[[1]]}, Drop[pts, 2]], 
                   SplineDegree -> deg],
               3, BSplineCurve[Rest[pts], SplineDegree -> deg]
               ];

       Function[{segments, pts},
               MapThread[ff,
                   {
                       segments[[All, 1]],
                       pts[[Range @@ (#1 - {1, 0})]] & /@
                           Partition[Accumulate[segments[[All, 2]]], 2, 1, {-1, -1}, 1],
                       segments[[All, 3]]
                       }
                   ]
               ] @@@ Transpose[List @@ curve]
       ]

Then for the example in the original post,

curve = FilledCurve[{{{1, 4, 3}, {1, 3, 3}, {1, 3, 3}, {1, 3, 3}}}, 
  {{{10.9614, 7.40213}, {10.9614, 10.2686}, {8.51663, 12.3137}, 
   {5.79394, 12.3137}, {3.05663, 12.3137}, {0.641063, 10.2686}, 
   {0.641063, 7.40213}, {0.641063, 4.53319}, {3.05663, 2.48813}, 
   {5.79394, 2.48813}, {8.53125, 2.48813}, {10.9614, 4.51856}, 
   {10.9614, 7.40213}}}];
curve2 = conversion[curve]

gives

{BezierCurve[{{10.9614, 7.40213}, {10.9614, 10.2686}, {8.51663, 
    12.3137}, {5.79394, 12.3137}}, SplineDegree -> 3], 
 BezierCurve[{{5.79394, 12.3137}, {3.05663, 12.3137}, {0.641063, 
    10.2686}, {0.641063, 7.40213}}, SplineDegree -> 3], 
 BezierCurve[{{0.641063, 7.40213}, {0.641063, 4.53319}, {3.05663, 
    2.48813}, {5.79394, 2.48813}}, SplineDegree -> 3], 
 BezierCurve[{{5.79394, 2.48813}, {8.53125, 2.48813}, {10.9614, 
    4.51856}, {10.9614, 7.40213}}, SplineDegree -> 3]}

and Graphics[curve2] produces

Answer 2

There is a public, but undocumented, function called GeometricFunctions`DecodeFilledCurve which helps to decode this type of undocumented FilledCurve:

GeometricFunctions`DecodeFilledCurve[
 FilledCurve[{{{0, 2, 0}, {0, 1, 0}, {0, 1, 0}, {0, 1, 0}, {0, 1, 0}}},  
  {{{12.887695983062486, 5.160000000000004}, 
    {1.8237311169604027, 5.160000000000004}, 
    {5.496094644083314, 22.410000000000004}, 
    {7.823731116960403, 22.410000000000004}, 
    {4.5834973678187225, 7.222500000000004}, 
    {13.319824330510414, 7.222500000000004}}}]]

which gives a documented form of FilledCurve:

FilledCurve[{{Line[{{12.8877, 5.16}, {1.82373, 5.16}}], 
 Line[{{5.49609, 22.41}}], Line[{{7.82373, 22.41}}], 
 Line[{{4.5835, 7.2225}}], Line[{{13.3198, 7.2225}}]}}]

The encoding/decoding scheme is and pretty obscure and may change in the future, which probably explains why this internal detail of the code is not documented. I would definitely not write code that depends on the undocumented syntax, and one could argue that Import(String) returning this syntax is a bug.

Answer 3

I hope it's not bad form to revive such an old thread, but FilledCurves can have more than one component. To handle things like glyphs for "o" and "i" that have multiple boundaries, you need to map @Heike's solution onto the components:

conversion[curve_] := Module[{ff},
  ff[i_, pts_, deg_] := 
    Switch[i,
      0, Line[Rest[pts]],
      1, BezierCurve[Rest[pts], SplineDegree -> deg],
      2, BezierCurve[Join[{pts[[2]], 2 pts[[2]] - pts[[1]]}, Drop[pts, 2]], 
           SplineDegree -> deg],
      3, BSplineCurve[Rest[pts], SplineDegree -> deg]];

  MapThread[
    Function[{segments, pts}, 
      MapThread[ ff, {segments[[All, 1]], 
        pts[[Range @@ (# - {1, 0})]] & /@ 
          Partition[Accumulate[segments[[All, 2]]], 2, 1, {-1, -1}, 1], 
        segments[[All, 3]]}]], List @@ curve]
];

Example:

txtbase = ImportString[ExportString["Mathematica", "PDF"], "PDF"];
txt = Cases[txtbase[[1, 1]], 
   c : FilledCurve[__] :> conversion[c], \[Infinity]];
{{xMax, xMin}, {yMax, yMin}} = ({Max[#], Min[#]} & /@ 
    Transpose[Reap[txt /. {x_Real, y_Real} :> Sow[{x, y}]][[2, 1]]]);
xRange = xMax - xMin;
xform[x_, y_] := {0.5 xRange Sin[1.4 \[Pi] (x/xRange - 1/2)], 
   1.2 (y (1 - 0.2 Cos[1.4 \[Pi] (x/xRange - 1/2)])
     - (yMax - y) 0.9 Cos[1.4 \[Pi] (x/xRange - 1/2)])};
Graphics[{txt /. {x_Real, y_Real} :> xform[x, y]}]

Answer 4

As far as I can tell, the only valid specifications for that first argument seem to be permutations of the input you have and similar lists of triplets.

• If the list is one element shorter than the second argument, all points in the second argument are points in the list, and the one corresponding to the element {0,2,0} in the first argument is the starting point for drawing the line.
• If the list is shorter than Length[secondElement]-1, then progressively, different points are "dropped out" of the shape. They are presumably then used as control points.
• If the list is the same length or longer, then you can't have a triplet {0,2,0}, but it works if they are all {0,1,0}.

For example, this creates a trapezoidal shape, dropping out the two points in the interior of the L.

Graphics@{Thickness[0.07507507507507508], Opacity[0.5], 
  Style[{FilledCurve[{{{0.2, 1, -1}, {0, 1, 0}, {0, 1, 0}, {0, 1,  0}}}, 
  {{{12.887695983062486, 5.160000000000004}, {1.82373111696040271, 
        5.160000000000004}, {5.496094644083314, 
        22.410000000000004}, {7.823731116960403, 
        22.410000000000004}, {4.5834973678187225, 
        7.222500000000004}, {13.319824330510414, 
        7.222500000000004}}}]}, Thickness -> 0.02]}