specify field width in Print

Question

I would like to format the output. For example, the following code gives

For[n=2,n<=10,n++,
  factorization =FactorInteger[n];
  length=Length[factorization];
  If[length==1,
    factorization =(Superscript@@@FactorInteger[n])[[1]],
    factorization =CenterDot@@(Superscript@@@FactorInteger[n])
  ];

  Print["n = ", n, " = ", factorization, ", number of prime factors = ", length];
]

But what I want is something similar to the following (but better alignment)

I know there is Grid, but I don't know how to use them in this current case. Also, I prefer a simpler solution (if there is), such as one can specify a "field width" like in the C language.

Answer 1

Grid is really quite useful for things like that if you can provide a finished list with results.

In this case I was to lazy to replace your procedural code (e.g. with Table) and just extracted the data you would have printed with Sow and Reap:

data = Reap[For[n = 2, n <= 10, n++, factorization = FactorInteger[n];
     length = Length[factorization];
     If[length == 1, 
      factorization = (Superscript @@@ FactorInteger[n])[[1]], 
      factorization = CenterDot @@ (Superscript @@@ FactorInteger[n])];
     Sow[{"n = ", n, " = ", factorization, 
       "; number of prime factors = ", length}];]][[2, 1]];

Grid[data]

Now you can start playing around with Grid options to get a format of your liking.

Answer 2

Supposing you want to print from inside the loop (not waiting for the loop to finish) you can use Grid on each line with specified field widths:

 Do[
      Print@Grid[{{
        RandomChoice[DictionaryLookup["*"]], "=", 
        RandomReal[{1, 10}]^RandomInteger[12]}},
          ItemSize -> {{10, Full, 8}},
          Alignment -> {{Right, Center, Right}}],
    {10}]

Another approach for nicely formatted monitoring..

out = {};
Monitor[
     Do[  Pause[1]; 
          AppendTo[out, {RandomChoice[DictionaryLookup["*"]], "=", 
                         RandomReal[{1, 10}]^RandomInteger[12]}],
       {10}], 
                Grid[out, Alignment -> {Right, Center, Right}]]