Computing the bounding boxes for Text objects

Question

Regardless of AspectRatio, the Text boxes overlap.

xmlObject = Uncompress[FromCharacterCode[
    Flatten[ImageData[Import["https://i.sstatic.net/AG4GB.png"], "Byte"]]]];
TreeForm[#, AspectRatio -> 1/3, ImageSize -> 700] &@
 Cases[xmlObject, XMLElement[tag : _, _, value : _] :> (tag -> value),
   Infinity]

More generally, I've asked Wolfram Research, Inc. about exposing bounding box coordinates for Text objects so that layout manager or engine can test overlap or compute tilings or disjoint positioning, but it appears to be complicated by the various Text options.

Does anyone know how to at least conservatively approximate the Text bounding box?

Answer 1

Here a test text. I use a gray background to show how large the bounding box actually is.

t = Graphics[Text["Test", BaseStyle -> {128}, Background -> Gray]]

d = ImageDimensions[ImageCrop[t]];
Graphics[{
  FaceForm[], EdgeForm[Red],
  Text["Test", {0, 0}, {-1, -1}, BaseStyle -> {128}],
  Rectangle[{0, 0}, Offset[d, {0, 0}]],
  PointSize[0.05], Point[{0, 0}]
}]

If you want a closer cut for your bounding box, just remove the Background option and ImageCrop again. However, note that offsets in the Text function are with respect to the bounding box Mathematica uses (indicated by the gray box).

t = Graphics[Text["Test", BaseStyle -> {128}]];
d = ImageDimensions[ImageCrop[t]];
Graphics[{
  FaceForm[], EdgeForm[Red],
  Text["Test", {0, 0}, {-.97, -0.6}, BaseStyle -> {128}],
  Rectangle[{0, 0}, Offset[d, {0, 0}]],
  PointSize[0.05], Point[{0, 0}]
}]

Note the {-.97, -0.6} offset?

Answer 2

If you are willing to settle for offset coordinates, you can use Rasterize to get the size of the text box.

text = Style["Text box box", Bold, Large, FontFamily -> "Times"]

textbox = Rasterize[text, "RasterSize"]

pos = {5, 10}

Graphics[{Text[text, pos, {-1, -1}], FaceForm[None], EdgeForm[Black], 
  Rectangle[pos, Offset[textbox, pos]]}, Frame -> True]

The key was the "RasterSize" element in Rasterize. You can use "BoundingBox" too, which will give you the baseline of the text.

You will notice that I drew the bounding box of the text (the Rectangle) using Offset coordinates, not in plot coordinates. You could use offset coordinates for every measurement and position specification of your text primitives to align them properly, but this will be inconvenient. It would be much better if we could easily convert between plot coordinates and offset coordinates. This is unfortunately quite messy and it will depend on the size of the graphic.

Offset coordinates are in printer's points. By default, Mathematica graphics are 360 points wide. If you know the exact PlotRange of your figure, and you can eliminate all padding outside the actual plot range (PlotRangePadding and ImagePadding, I'm not sure about ImageMargins), then you can use the known plot width to convert between offset and plot coordinates. Unfortunately, this conversion will only be valid for a given size of the graphic (the default size). It will not be valid any more if you resize it.