3
$\begingroup$

I am looking to find a consistent way of finding integrals that result in inverse trig functions. I have been able to convert the output of

Integrate[D[ArcSin[2 x/3], x], x]

being

I Log[-2 I x + Sqrt[9 - 4 x^2]]

into an ArcTan form, which I then convert to an ArcSin form, though this form still differs to the original ArcSin[2x/3], being a translated Pi/2 units positively in the vertical axis and it does not work on a more general scale. An ideal solution to my issue would output ArcSin[2x/3] in this case and would work on a more general scale eg. D[ArcSin[2x+1/3], giving only real solutions to integrals.

Improve this question
New contributor
Bot 1 is a new contributor to this site. Take care in asking for clarification, commenting, and answering. Check out our Code of Conduct.
$\endgroup$
2
  • 1
    $\begingroup$ I get ArcTan[(2 x)/Sqrt[9 - 4 x^2]], which is equivalent (no translation) to ArcSin[2x/3]. (V14.1) $\endgroup$
    – Michael E2
    Commented Dec 12 at 14:53
  • 2
    $\begingroup$ It appears that the next release will give the desired result. In[2]:= Integrate[D[ArcSin[2 x/3], x], x] // InputForm Out[2]//InputForm= ArcSin[(2*x)/3] I don't know if that was intentional or lucky, but with Integrate I'm inclined to expect it's the latter. $\endgroup$
    – Daniel Lichtblau
    Commented Dec 12 at 17:32

4 Answers 4

Reset to default
4
$\begingroup$
  • use assumptions to specify that variables are real and constrained (some experimentation needed)
  • use definite integration because what you ask for is not possible in general for indefinite integrals
Integrate[D[ArcSin[2 x/3], x], {x, 0, y}, Assumptions -> -3/2 < y < 3/2]

(*    ArcSin[2 y/3]     if y >= 0    *)
Improve this answer
$\endgroup$
3
$\begingroup$

An ideal solution to my issue would output ArcSin[2x/3]

<< Rubi`
Int[D[ArcSin[2 x/3], x], x]

enter image description here

To install Rubi, this is the command

PacletInstall["https://rulebasedintegration.org/Rubi-4.16.1.0.paclet"]
Improve this answer
$\endgroup$
2
$\begingroup$

As I mentioned, I already get a real result:

overlaid[n_] := Reverse@Table[AbsoluteThickness[1.5 k], {k, n}]; (*plotstyle*)
$Version
primitive = ArcSin[2 x/3];
assum = FunctionDomain[D[primitive, x], x]
antideriv = Integrate[D[primitive, x], x] (* could use Assumptions here *)
Plot[{antideriv, primitive}
 , {x, MinValue[{x, assum}, x], MaxValue[{x, assum}, x]}
 , PlotStyle -> overlaid[2]]

Plot showing antideriv and primitive match

Here's a way to obtain a real result from the OP's reported output with a generically equal derivative:

Assuming[assum,
 I Log[-2 I x + Sqrt[9 - 4 x^2]] // Re // ComplexExpand // 
   ReplaceAll[a_Arg :> ArcSin@Sin@a] // FullSimplify
 ]
(*  ArcSin[(2 x)/3]  *)

We took the real part and converted Arg[] to the desired trig form. Of course, if there are mixed trig functions, such as primitive = ArcSin[2 x/3] - ArcCos[2 x/3], it may be impossible to split up Arg[] to get primitive; probably theoretically impossible, as it is with inverting Integrate[D[Sin[x]^2, x], x], Integrate[D[-Cos[x]^2, x], x], and Integrate[D[Sin[2x], x], x].

Improve this answer
$\endgroup$
0
$\begingroup$

Use Rubi. It makes integration so much easier (I'm still new to it but it seems very impressive). Int[D[ArcSin[2 x/3], x], x]

outputs:

(ArcSin[(2 x)/3])

Look into Rubi if you are having trouble getting nicer-form integrals.

Improve this answer
New contributor
Bot 1 is a new contributor to this site. Take care in asking for clarification, commenting, and answering. Check out our Code of Conduct.
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.