Apply Jacobi-Anger expansion and return infinite sum

Question

I have an expression

Sin[z Sin[th]]

I want Mathematica to apply the Jacobi Anger expansion, and it works:

FourierTrigSeries[Sin[z Sin[th]], th, 1]

gives 2 BesselJ[1, z] Sin[th]

However, I would like it give the infinite sum

2 Sum[BesselJ[2n-1,z]Sin[(2n-1)th],{n,1,Infinity}]

How should I convince Mathematica to do so?

Answer 1

FourierTrigSeries (or FourierSinCoefficient can be used in this case for simplicity) returns correct result but for some reason Mathematica is not able to simplify the coefficients. For example the first four coefficients are returned in proper form but the fifth can be further simplified which Mathematica fails on.

But if we provide it the correct result 2 BesselJ[5, z] then Mathematica is able to verify that the expressions are equivalent - i.e. returns True.

FourierSinCoefficient[Sin[z Sin[th]], th, #] & /@ Range[5]
FullSimplify[Last@%]
FullSimplify[Last@%% == 2 BesselJ[5, z]]

---

{2 BesselJ[1, z], 0, 2 BesselJ[3, z], 0,
(2 (z (-48 + z^2) BesselJ[1, z] - 12 (-16 + z^2) BesselJ[2, z]))/z^3}

(2 (z (-48 + z^2) BesselJ[1, z] - 12 (-16 + z^2) BesselJ[2, z]))/z^3

True

Answer 2

Mathematica can't compute the series, but using a workaround:

"14.1.0 for Microsoft Windows (64-bit) (July 16, 2024)"

2 Sum[BesselJ[2 n - 1, z] Sin[(2 n - 1) t], {n, 1, Infinity}](*Can't compute.Gives Input*)

2*InverseLaplaceTransform[Sum[LaplaceTransform[BesselJ[2 n - 1, z] 
Sin[(2 n - 1) th], z, s],{n, 1, Infinity}] // FullSimplify, s, z](*Workaround*)

(* Sin[z Sin[th]] *)

then we have:

$$2 \sum _{n=1}^{\infty } J_{2 n-1}(z) \sin ((2 n-1) \text{th})=\sin (z \sin (\text{th}))$$

We can check:

f[z_, th_] := 2 NSum[BesselJ[2 n - 1, z] Sin[(2 n - 1) th], {n, 
1, Infinity}]; g[z_, th_] := Sin[z Sin[th] // N]
{f[2, 3], g[2, 3]}

(* {0.278508, 0.278508} *)

EDITED 29.11.2024

Using @azerbajdzan answer and workaround we can find more coefficients up too 22:

A = FourierSinCoefficient[(-1)^m/(1 + 2 m)!*( z Sin[th])^(1 + 2 m) // 
PowerExpand, th, n] // FullSimplify
B = Sum[Table[A, {n, 1, 22}] // FullSimplify, {m, 0, Infinity}]

(*{2 BesselJ[1, z], 0, 2 BesselJ[3, z], 0, 2 BesselJ[5, z], 0, 
2 BesselJ[7, z], 0, 2 BesselJ[9, z], 0, 2 BesselJ[11, z], 0, 
2 BesselJ[13, z], 0, 2 BesselJ[15, z], 0, 2 BesselJ[17, z], 0, 
2 BesselJ[19, z], 0, 2 BesselJ[21, z], 0}*)