Adding a multitude of conditions into Solve from two lists. One list for variables and the other list of coefficients

Question

Apologies if this has been answered before but I can't find it.

My situation is I have a list of variable expressions and another list of what I want to equate each one to. And I want to combine these into conditionals which will go into Solve.

I'll use a code box to show what I mean with a trivial example - my real lists could be quite long.

variableExpressions = {a+b+c, a-b+c, a+b-c etc etc};
myCoefficients = {5, 7, 2, etc etc};

(* What I want to do is plug into solve like the following *)

Solve[a+b+c==5 && a-b+c==7 && a+b-c ==2 etc etc etc ,{a,b,c}, PositiveIntegers]

In a real case I may have quite many variable expressions and many what I call coefficients (possibly in the hundreds) to the point hand entering them is not feasible.

I'm sure someone knows how to do this or can reference where this has been done before.

Any help/ideas is much appreciated.

Answer 1

Method 1

variableExpressions = {a + b + c, a - b + c, a + b - c};
myCoefficients = {5, 7, 2};

sol =Solve[MapThread[Equal, {variableExpressions, myCoefficients}], 
 Variables@variableExpressions]

---

$\left\{\left\{a\to \frac{9}{2},b\to -1,c\to \frac{3}{2}\right\}\right\}$

You can solve using PositiveIntegers but the solution will be {} for this particular case.

---

Method 2

Since these are linear equations:

m = Last@Normal@
   CoefficientArrays[variableExpressions, 
    Variables@variableExpressions]

sol2 = Thread[
  Variables@variableExpressions -> LinearSolve[m, myCoefficients]]

$\left\{a\to \frac{9}{2},b\to -1,c\to \frac{3}{2}\right\}$

---

Check

MapThread[Equal, {variableExpressions, myCoefficients}] /. sol

{{True, True, True}}

Answer 2

If you have some scalar operator (in your case "Equal) that you want to apply on lists, you can do this with either "Thread" or "MapThread". E.g. your example:

variableExpressions = {a + b + c, a - b + c, a + b - c };
myCoefficients = {5, 7, 2};
Thread[variableExpressions == myCoefficients]

{a + b + c == 5, a - b + c == 7, a + b - c == 2}

Or with MapThread:

MapThread[Equal, {variableExpressions, myCoefficients}]

{a + b + c == 5, a - b + c == 7, a + b - c == 2}