Is there a more concise method to solve the problem of finding tangent lines to curves?

Question

The question is:

If the tangent line to the curve $y=e^x+x$ at point $(0,1)$ is also a tangent line to the curve $y=\ln(x+1)+a$, then $a=$ _______

---

My method is like this, very cumbersome!

Clear["`*"]
f[x_] = E^x + x;
pt = {0, 1}; k1 = f' /. x -> pt[[1]]
line = y - 1 == k1 x // Simplify
g[x_] = Log[x + 1] + a
k2 = D[g[x], x]
sol = Reduce[{k1 == k2}, x] // ToRules
sol1 = Reduce[line /. sol, y] // ToRules
pt1 = {x, y} /. Thread[{x, y} -> {sol // Values, sol1 // Values}] // 
  Flatten[#, 1] &
Reduce[{y == Log[x + 1] + a, x == pt1[[1]], y == pt1[[2]]}, a]

This problem does not require drawing, just calculate the results of the corresponding parameters.

Is there a more concise method to solve the problem?

Answer 1

Method-1

• RegionEqual.

Clear["Global`*"];
f[x_] := E^x + x;
g[x_] := Log[x + 1] + a;
line1 = InfiniteLine[{0, f[0]}, {1, f'[0]}];
line2 = InfiniteLine[{x0, g[x0]}, {1, g'[x0]}];
sol = Solve[RegionEqual[line1, line2], Method -> Reduce]

{{a -> Log[2], x0 -> -(1/2)}}.

• plotting

Plot[{Callout[f[x]], Callout[g[x]]} /. sol[[1]] // 
  Evaluate, {x, -.9, .6}, Axes -> None, 
 Epilog -> {{Red, line1, line2, Red, PointSize[.02], Point@{0, f[0]}, 
     Point@{x0, g[x0]}} /. sol[[1]]}]

Method-2

Clear[f, g, pt1, slope1, slope2, sol];
f[x_] := E^x + x;
g[x_] := Log[x + 1] + a;
pt1 = {0, f[0]};
slope1 = f'[0];
slope2 = g'[x];
sol = Solve[{slope2 == slope1}]
Solve[{pt1 ∈ InfiniteLine[{x, g[x]}, {1, slope2}]} /. 
  sol[[1]]]

{{x -> -(1/2)}}.

{{a -> Log[2]}}.

Answer 2

Here's a possible easier solution.

f[x_] := Exp[x] + x
g[x_] := Log[x + 1] + a
Reduce[ForAll[{x, y}, y - g[x0] - g'[x0] (x - x0) == y - f[0] - f'[0] (x + 0)]]
(* x0 == -(1/2) && a == Log[2] *)

Answer 3

f[t_] := {t, Exp[t] + t}
tv = (D[f[t], t] /. t -> 0);
tg[s_] := tv  s + {0, 1};
g[t_] := {t, Log[1 + t] + a};
sol = Solve[g'[t] == tv, t][[1]]
asol = Solve[g[t] == tg[t] /. sol, a][[1]]
h = g[t] /. asol
ParametricPlot[{f[t], h, tg[t]}, {t, -1, 1}, 
 Epilog -> {Red, PointSize[0.04], Point[tg[t] /. {{t -> 0}, sol}]}, 
 PlotLegends -> "Expressions", AspectRatio -> Automatic]

Answer 4

You can check if this does what you want.

x0 = 0; y0 = 1;
f1 = Exp[x] + x;
f2 = Log[x + 1] + a
slope = D[f1, x] /. x -> x0
equationOftangent = slope*x + y0
aSolution = SolveValues[f2 == equationOftangent, a]

Verify

p1 = Plot[{equationOftangent, f1}, {x, -1, 1}, 
          Epilog -> {Red, PointSize[.03], Point[{x0, y0}]}]

p2 = Plot[f2 /. a -> aSolution , {x, -1, 1}]

Answer 5

According to Najib Idrissi's answer, the code also can be written as follows:

Clear["`*"]
f[x_] := E^x + x; g[x_] := Log[x + 1] + a;
Reduce[ForAll[{x, y}, y - 1 == f'[0] x, y - g[x0] == g'[x0] (x - x0)]]