Plotting two 3D lines causes FE crash

Question

The code below causes the Front End to CRASH. I came across this problem in some code that is very complicated, so I narrowed down the problem to a very simple task, to plot a couple of lines.

(* WARNING: CAUSES CRASH *)
Block[{p0 = {2, 0, 0}, seed = 2, n = 11},
 SeedRandom[seed];
 Graphics3D[{Line@
    Table[p + 3 {-0.5 + Cos[t], Sin[t], 0.5 t}
     , {p, p0 + # & /@ RandomReal[{-1, 1}, {n, 3}][[-2 ;;]]}
     , {t, -4, 4}]}
  (* no bug if PlotRange->Automatic *)
  , PlotRange -> ({# - 4.2, # + 4.2} & /@ p0)
  ]
 ]

Here's my version/system info

"14.0.0 for Mac OS X ARM (64-bit) (December 13, 2023)"

Questions:

1. Are there any workarounds?

2. On which systems does this problem arise?

Reported to WRI: [CASE:5121211]

Update: WRI responded with an even simpler example of the bug, which can also be avoid by using the "BSPTree" rendering engine:

Graphics3D[
 Line[{{{0, 0, -6}, {3, 0, 0}, {0, -3, 6}},{{0, 3, -6}, {-3,0,-3}}}],
 PlotRange -> {{-2, 2},{-2, 2}, {-2, 4}}] 

Answer 1

I've found two workarounds, using a different rendering engine and mapping Line[] over the list of lists of coordinates. The first seems easiest to me from a programming viewpoint, especially if the bug is ever fixed.

Block[{p0 = {2, 0, 0}, seed = 2, n = 11},
 SeedRandom[seed];
 Graphics3D[{Line@
    Table[p + 3 {-0.5 + Cos[t], Sin[t], 0.5 t}
     , {p, p0 + # & /@ RandomReal[{-1, 1}, {n, 3}][[-2 ;;]]}
     , {t, -4, 4}]}
  (* no bug if PlotRange->Automatic *)
  , PlotRange -> ({# - 4.2, # + 4.2} & /@ p0)
  (* FIX: Graphics3DRenderingEngine *)
  , BaseStyle -> 
   RenderingOptions -> {"Graphics3DRenderingEngine" -> "BSPTree"}]
 ]

Block[{p0 = {2, 0, 0}, seed = 2, n = 11},
 SeedRandom[seed];
 Graphics3D[{Line /@ (* <-- FIX: Map *)
    Table[p + 3 {-0.5 + Cos[t], Sin[t], 0.5 t}
     , {p, p0 + # & /@ RandomReal[{-1, 1}, {n, 3}][[-2 ;;]]}
     , {t, -4, 4}]}
  (* no bug if PlotRange->Automatic *)
  , PlotRange -> ({# - 4.2, # + 4.2} & /@ p0)
  ]
 ]

I tried rewriting it as GraphicsComplex, but it crashed my front end.