4
$\begingroup$

I had asked a question here about visualization of Riemann surface and got an answer:

My function is:

$$g (z) = (1 - a^2/z) (1 - 1 /z),$$

where $0 < a < 1$. And the branch cut is from $a^2 \to 1$.

The answer by @eldo reads (for $a = \sqrt{0.5}$):

f = Sqrt[(1 - Sqrt[0.5]^2/z) (1 - 1/z)];

Riemann = ResourceFunction["RiemannSurfacePlot3D"];

Riemann[f == w, Im[w], {z, w}, Axes -> {True, True, False}, Boxed -> False, PlotPoints -> 48, PlotStyle -> GrayLevel[0.7], ViewPoint -> {0, 0, 100}]

which looks:

enter image description here

My question is: How can I mark branch cut by, for example, a white line on this plot?

$\endgroup$
1
  • $\begingroup$ Try adding "ShowBranchPoints" -> True to your call to RiemannSurfacePlot3D. $\endgroup$
    – MarcoB
    Dec 20, 2023 at 16:01

2 Answers 2

3
$\begingroup$
a = 1/2;
ComplexPlot3D[
  Sqrt[(-1 + z)/z] Sqrt[(-a^2 + z)/z], {z, -(1/4) - (3 I)/4, 
   5/4 + (3 I)/4}, BoxRatios -> {1, 1, 3/2}];
ParametricPlot3D[{z, 0, Abs[Sqrt[(-1 + z)/z] Sqrt[(-a^2 + z)/z]]}, {z,
    a^2, 1}, PlotStyle -> Directive[Black, Dashed, Thick]];
Show[%%, %]
Clear[a]

enter image description here

$\endgroup$
0
2
$\begingroup$
f = Sqrt[(1 - Sqrt[0.5]^2/z) (1 - 1/z)];

Riemann = ResourceFunction["RiemannSurfacePlot3D"];

As MarcoB already commented, RiemannSurfacePlot3D has an option called "ShowBranchPoints"

Riemann[f == w, Im[w], {z, w},
 Axes -> True,
 ColorFunction -> (Directive[Opacity[0.8], Hue[(Arg[#2] + 0.5)/(2 Pi)]] &),
 PlotPoints -> 48,
 "ShowBranchPoints" -> True]

enter image description here

But it doesn't have options to draw mesh lines. So we regard it from above and draw appropriate FaceGrids:

Riemann[f == w, Im[w], {z, w},
 Axes -> {True, True, False},
 Boxed -> False,
 ColorFunction -> (Directive[Opacity[0.8], Hue[(Arg[#2] + 0.5)/(2 Pi)]] &),
 FaceGrids -> {{{0, 0, 1}, {{-1.5, -1, 0, 0.5, 1, 1.5}, {0}}}},
 FaceGridsStyle -> Blue,
 PlotPoints -> 48,
 ViewPoint -> {0, 0, 100}]

enter image description here

We can see that the two branch points are located at {0.5, 0.0} and {1.0, 0.0}.

$\endgroup$
0

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.