Listing iterations inside a while loop

Question

I wrote a code for bisection method root approximation. However, I wanted to know the value of the root every iteration. I tried using the Union function to save each iterated value in a set but it saves the numbers in increasing order.

I am reading on NestWhileList but I am new to Mathematica and I still do not understand it much. Is there a way to use it?

f[x_] := x - E^(-1.2*x);
a = 0.5; b = 1;(*a<b*)
c = 0;
\[Epsilon] = 0.001; (*error*)
iter = 0; 
cList = {};


If[f[a]*f[b] > 0, 
 Print["Conditions of Bisection Method are not met. Disregard \
solution below."], "See solution below"]

While[Abs[b - a]/2 > \[Epsilon],
  
  c = (a + b)/2;
  iter = iter + 1; (*number of iterations*)
  cList = cList \[Union] {c};
  
  f[a];(*left-hand side*)
  f[b];(*right-hand side*)
  f[c];(*mid-point*)
  
  If[f[a]*f[c] < 0, b = c, a = c];
  ];

N[c] (*root*)
iter(*number of iterations*)
cList (*iterated roots*)

Answer 1

I assume you want to collect the values of c in cList?

Just replace your loop with

cList=First@Last@Reap@While[Abs[b-a]/2>ϵ,
      c=(a+b)/2;
      iter=iter+1;(*number of iterations*)
      Sow[c];
      If[f[a]*f[c]<0,b=c,a=c]
];

Lookup help on Sow and Reap

Btw, iter=iter+1 can be written as iter++ in Mathematica.

Answer 2

Your function and test:

f = x |-> x - E^(-1.2*x);  (* head is Function *)
test[{a_Real, b_Real}] := Abs[b - a]/2 > 0.001

Your iterative step, used with NestWhileList (as requested):

step[f_Function, {a_Real, b_Real}] /; a < b :=
 With[{c = (a + b)/2.}, If[f[a]*f[c] < 0, {a, c}, {c, b}]]
Mean /@ Most@NestWhileList[step[f, #] &, {0.5, 1.}, test]

A closely related alternative, using Sow:

sowStep[f_Function, {a_Real, b_Real}] /; a < b :=
 With[{c = (a + b)/2.}, Sow[c]; If[f[a]*f[c] < 0, {a, c}, {c, b}]]
First@Last@Reap@NestWhile[sowStep[f, #] &, {0.5, 1.}, test]

The latter has a bit less computational redundancy, although that really does not matter here.

Answer 3

Using NestWhileList

bm[f_, {a_, b_}] := 
 With[{c = (a + b)/2}, If[f[a] f[c] < 0, {a, c}, {c, b}]]
w[f_, a_, b_, e_] := 
 Mean /@ NestWhileList[bm[f, ##] &, {a, b}, 
   Abs[#[[2]] - #[[1]]]/2 > e &]

Examples

1.

f[x_] := x - E^(-1.2*x);
rt = x /. FindRoot[f[x], {x, 1}]
ans = w[f, 0.5, 1, 0.0001];
ListPlot[ans, GridLines -> {None, {rt}}]

2. functions $x^2-2$, $\sin (x)$, $\cos (x)$

    ListPlot[w[#^2 - 2 &, 0., 3, 0.0001], GridLines -> {None, {Sqrt[2]}}]
    ListPlot[w[Sin, 2, 4, 0.0001], GridLines -> {None, {Pi}}]
    ListPlot[w[Cos, 1, 2, 0.0001], GridLines -> {None, {Pi/2}}]