Vectorizing in 3D environments

Question

The following code

ParametricPlot3D[{{Cos[t], Sin[t], t/2}, {Cos[t + Pi], Sin[t + Pi], t/2}, If[
   EvenQ[Floor[4 t/Pi]], {Cos[t], Sin[t], t/2}, {Cos[t + Pi], 
    Sin[t + Pi], t/2}]}, {t, 0, 4 Pi}, PlotStyle -> Black, 
 Boxed -> False, 
 ViewPoint -> {Infinity, 0, 0}, ViewVertical -> {0, -1, 0}, 
 Axes -> False]

yields

I want to export this as a vectorized image. However, when I save it as either PDF or SVG, I get some antialiasing artifacts. For example, zooming in,

Is there anyway to solve this?

Answer 1

• replace ViewPoint -> {Infinity, 0, 0} to ViewPoint -> {1, 0, 0}, ViewProjection -> "Orthographic"

plot3 = ParametricPlot3D[{{Cos[t], Sin[t], t/2}, {Cos[t + Pi], 
    Sin[t + Pi], t/2}, 
   If[EvenQ[Floor[4 t/Pi]], {Cos[t], Sin[t], t/2}, {Cos[t + Pi], 
     Sin[t + Pi], t/2}]}, {t, 0, 4 Pi}, PlotStyle -> Black, 
  Boxed -> False, ViewPoint -> {1, 0, 0}, 
  ViewProjection -> "Orthographic", ViewVertical -> {0, -1, 0}, 
  Axes -> False]

• the same way as my previous answer to get a vector format pdf. https://mathematica.stackexchange.com/a/275712/72111

plot2 = Graphics[plot3[[1]] /. {x_Real, y_Real, z_Real} :> {z, y}]
Export["test.pdf", plot2]
SystemOpen["test.pdf"]

Answer 2

Not really an answer, but a solution to my particular problem:

helix1[t_] := {Sin[t], t/2}
helix2[t_] := {Sin[t + Pi], t/2}
connectingLine[t_] := 
 If[EvenQ[Floor[4 t/Pi]], {Sin[t], t/2}, {Sin[t + Pi], t/2}]
img = Rotate[
  ParametricPlot[{helix1[t], helix2[t], connectingLine[t]}, {t, 0, 
    4 Pi}, PlotStyle -> Black, Axes -> False], Pi/2]
Export["img.pdf", img]

This produces a Graphics object which I can easily export as a vector, without the antialiasing issue.

The general question is somewhat trickier, as it has to do with how Mathematica handles the export of Graphics3D objects. Ultimately, my "solution" is merely analytical, where a projection onto a 2D plane is relatively easy, given the ViewPoint setting in the original ParametricPlot3D. This has already been partially discussed before in this question, and it would be interesting to know whether there is a reasonably general way of guaranteeing lossless vectorized images from 2D representations of 3D plots.

I am not too familiar with vector graphics rendering, but it would be interesting to know whether this has been discussed before within Mathematica. In particular, whether ViewPoint settings alone could be used to directly infer the 2D projection, rather than merely using standard vectorizing techniques, where information would be lose.