Stop Computation - Is Exit[] overkill?

Question

The following example either finds a factor of the number $n$ or returns a message saying that the number in question is prime (I specifially wrote this to demonstrate my question below).

n = 125;
For[i = 2, i <= Sqrt[n], i++,
    If[Mod[n, i] == 0, Print["Factor found: ", i]; Break[];]
 ]
If[i <= Sqrt[n], Exit[];]
Print[n, " is prime."]
...

I know I could simply include the last Print statement in the if-condition, but I am specifically looking for a command that makes Mathematica skip the last Print statement (and all other statements that might come thereafter...). I tried Break, Abort and Interrupt, but none have the desired effect.

Now the commands Exit and Quit work, but they terminate the entire Mathematica kernel, which is a bit of an overkill. How could I bypass this issue? I need something like SkipRemainingCommands.

Answer 1

After comment:

Abort will help You:

(Do[
  If[Mod[n, i] == 0, Print["factor found: ", i]; Abort[];]
  , {i, 2, Round@Sqrt@n}];
 Print[n, " is prime."];)

factor found: 2
$Aborted

I understand this behavior of ( ) rather intuitively so I will wait for someone smarter. I assume this is forcing procedures to create CompoundExpression, which is also created if You avoid line break between Your loop and last Print:

Do[ If[Mod[n, i] == 0, Print["factor found: ", i]; Abort[];]
  , {i, 2, Round@Sqrt@n}]; Print[n, " is prime."];

factor found: 2
$Aborted

---

Before comment:

It might be good to show/try/learn different way to do this.

Goto: This is not elegant and my friend once have told me "do not use Goto in C++", but it works in simple cases:

f[n_] := Module[{},
  Do[
   If[Mod[n, i] == 0, Print["factor found: ", i]; Goto["End"]]
   , {i, 2, Round@Sqrt@n}];
  Print[n, " is prime."];
  Label["End"];
  ]
f[15]

factor found: 3

Catch/Throw mentioned in comments:

n = 12;
Catch[
 Do[
  If[Mod[n, i] == 0, Throw@Print["factor found: ", i];]
  , {i, 2, Round@Sqrt@n}];
 Print[n, " is prime."];
 ]

factor found: 2

Answer 2

I agree with using Goto and Label in this situation. We can replace the For with While by testing the greatest factors. Of course, any number mod 1 is 0, which gets us out of the While.

Block[{n = 115, i = Ceiling[Sqrt[n]]},
  While[0 != Mod[n, --i]];
  If[i != 1, Print["Factor found ", n]; Goto["end"]];
  Print[n, " is prime"];
  (*...other code...*)
  Label["end"];
]

Answer 3

Use Break to get out of the loop, saving the test result for later use:

For[ ....  If[ notprime = (Mod[n, i] == 0) , Break[]] ... ];
If[notprime , Primt["not prime a factor is",i] , Print["Prime" ] ]

( I don't even use goto in Fortran code )