Struggling to get Solve to accept assumptions

Question

I can't get Solve to solve the following two equations under the appropriate assumptions.

When I enter

fs = I Cos[(s + t)/2] Sin[beta/2] - 1/2 Cos[beta/2] Sin[(s - t)/2]
ft = I Cos[(s + t)/2] Sin[beta/2] + 1/2 Cos[beta/2] Sin[(s - t)/2]
Solve[
  {fs == 0, ft == 0}, {s, t}, 
  Assumptions -> 
    Element[beta, Reals] && (beta > 0) && (beta < Pi/2) && 
      (s >= 0) && (s <= 2*Pi) && (t >= 0) && (t <= 2*Pi)
]

I get the following result:

{{s -> ConditionalExpression[π/2, Cos[beta/2] > 0 || Cos[beta/2] < 0], 
  t -> ConditionalExpression[π/2, Cos[beta/2] > 0 || Cos[beta/2] < 0]}, 
  {s -> ConditionalExpression[(3 π)/2, Cos[beta/2] > 0 || Cos[beta/2] < 0], 
  t -> ConditionalExpression[(3 π)/2, Cos[beta/2] > 0 || Cos[beta/2] < 0]}}

But I have told it that beta is real, that beta > 0 and beta < Pi/2. So why is it still putting a ConditionalExpression on the value of Cos[beta] being positive or negative?

Answer 1

With your definitions of fs and ft, try this:

assumptions = {0 < beta < Pi/2, 0 <= s <= 2Pi, 0 <= t <= 2Pi};
Assuming[assumptions, Simplify@ Solve[{fs == 0, ft == 0}, {s, t}]]

(* Out: {{s -> π/2, t -> π/2}, {s -> (3 π)/2, t -> (3 π)/2}} *)

This will simplify the conditions away using the same assumptions you used for Solve. Note that this takes advantage of the fact that Solve now takes assumptions, a recent change in the language, but of course you are aware of that, since you were using it in your original code.