Generating a large number of data points of a function subjected to multiple constraints

Question

In continuation to my previous question, I have (a slightly modified) function
f[x_,y_,z_,a_,b_,c_]:=x^2 a b + xy b c+ yz c a + z^3 abc , and I want to randomly choose values of x,y,z,a,b,c (with constraints that all $x,y,z$, and $a,b,c$ are positive, and Sqrt[x^2+y^2+z^2]<=1 and a+b+c=1) and plot f[x,y,z,a,b,c] against Sqrt[x^2+y^2+z^2] for say 100 points $(x,y,z,a,b,c)$.

I am editing this question with additional constraints given by four inequalities $|x\pm y| \le |1\pm z|$ which simplify to $z \ge x+y-1; ~z\le -x+y+1;~z\le x-y+1;~z \ge -x-y-1.$

How can one take into account these?

EDIT: It was "all ... and $a,b,c$ are positive" and not just $a$.

Answer 1

$Version

(* "13.1.0 for Mac OS X x86 (64-bit) (June 16, 2022)" *)

Clear["Global`*"]

f[x_, y_, z_, a_, b_, c_] := 
  x^2*a*b + x*y*b*c + y*z*c*a + z^3*a*b*c

FullSimplify[Abs[x + y] <= Abs[1 + z] &&
  Abs[x + y] <= Abs[1 - z] &&
  Abs[x - y] <= Abs[1 + z] &&
  Abs[x - y] <= Abs[1 - z] &&
  x > 0 && y > 0 && z > 0 &&
  Sqrt[x^2 + y^2 + z^2] <= 1]

(* x + y + z <= 1 && x > 0 && y > 0 && z > 0 *)

param = FindInstance[{x > 0, y > 0, z > 0, a > 0, 
    Sqrt[x^2 + y^2 + z^2] <= 1, a + b + c == 1, x + y + z <= 1}, 
  {x, y, z, a, b, c}, Reals, 100];

pts = Simplify[{Sqrt[x^2 + y^2 + z^2], f[x, y, z, a, b, c]} /. #] & /@
    param;

ListPlot[pts, Frame -> True,
 FrameLabel -> {Sqrt[x^2 + y^2 + z^2], 
   HoldForm@f[x, y, z, a, b, c]}]

EDIT: Expanding the PlotRange

ListPlot[pts, Frame -> True,
 FrameLabel -> {Sqrt[x^2 + y^2 + z^2],
   HoldForm@f[x, y, z, a, b, c]},
 PlotRange -> All]

Or

ListPlot[pts, Frame -> True,
 FrameLabel -> {Sqrt[x^2 + y^2 + z^2],
   HoldForm@f[x, y, z, a, b, c]},
 PlotRange -> All,
 ScalingFunctions -> "SignedLog"]

Answer 2

Try

u=RandomReal[{0,1},{400,5}]; (*generate enough points to have >=100 acceptable points*)
v=Map[({x,y,z,a,b}=#;{x,y,z,a,b,1-a-b})&,u];(*c isn't really "random", calculate it*)
w=Take[Select[v,({x,y,z,a,b,c}=#;x^2+y^2+z^2<=1&&x+y-1<=z<=-x+y+1&&z>=-x-y-1)&],100];
f[x_,y_,z_,a_,b_,c_]:=x^2*a*b+x*y*b*c+y*z*c*a+z^3*a*b*c;
ListPlot[Map[({x,y,z,a,b,c}=#;{f[x,y,z,a,b,c], Sqrt[x^2+y^2+z^2]})&,w]]

Ah! Notice that I (or possibly the OP) made a mistake. He wrote "with constraints that all x,y,z, and a are positive" and I implemented "with constraints that all x,y,z,a,b are positive." If b really can be -9999999 then my code will need to be modified, perhaps in a similar way to how I generated c after the fact, to provide a different random range for b. And he didn't provide any bounds on the range of a, so it might possibly be 9999999. Both of those are going to make a VERY different plot. That just shows that you have to test my code VERY carefully to make certain that you have discovered all of my errors.