What's wrong in my custom distribution?

Question

i want to write this function

dist = ProbabilityDistribution[{(x/\[Lambda])^\[Alpha]}, {x, 0, \[Infinity]}, Assumptions -> {\[Lambda] > 0 && \[Lambda] > x, \[Alpha] > 0}]
data = {2.8, 1.8, 3.2, 5.0, 2.4, 4.8, 2.9, 2.9, 2.3, 3.2, 2.3, 2.0, 1.9, 3.3, 4.4, 6.7, 4.3, 1.9, 2.2, 3.3, 2.1, 4.0, 2.0, 3.1, 3.8,  3.1, 3.2, 3.4, 2.8, 2.1, 3.1}

mle = FindDistributionParameters[data, dist, ParameterEstimator -> {"MaximumLikelihood", Method -> "FindMaximum", MaxIterations -> 10000}]

but no result show it' show like pic below

please anyone can help me

Answer 1

Here is an explanation why Mathematica and other software packages have trouble with this particular probability distribution.

dist = ProbabilityDistribution[(x/λ)^α, {x, 0, λ}, Assumptions -> {λ > x, α > 0}, 
   Method -> "Normalize"];

data = {2.8, 1.8, 3.2, 5.0, 2.4, 4.8, 2.9, 2.9, 2.3, 3.2, 2.3, 2.0, 
   1.9, 3.3, 4.4, 6.7, 4.3, 1.9, 2.2, 3.3, 2.1, 4.0, 2.0, 3.1, 3.8, 
   3.1, 3.2, 3.4, 2.8, 2.1, 3.1};

(* Determine log of the likelihood and do a bunch of simplifications *)
logL = Simplify[LogLikelihood[dist, data], Assumptions-> λ > Max[data]] //.
  Log[a_ b_] -> Log[a] + Log[b] /. Log[a_^b_] -> b Log[a] /.
  Log[Power[a_,-1]] -> -Log[a] // Expand

(* 33.497 α + 31 Log[1 + α] - 31 Log[λ] - 31 α Log[λ] *)

We see that because $\alpha>0$, $\lambda$ needs to be made as small as possible to maximize the log of the likelihood. The smallest value possible is the maximum of the data values.

But when maximum likelihood estimators are on the border of possible values for a parameter, that can cause difficulties.

So the maximum likelihood value for $\alpha$ can be found with the following:

FindMaximum[{logL /. λ -> Max[data], α > 0}, α]
(* {-58.4039, {α -> 0.217198}} *)

Answer 2

$Version

(* "13.1.0 for Mac OS X x86 (64-bit) (June 16, 2022)" *)

Clear["Global`*"]

dist = ProbabilityDistribution[(x/λ)^α, {x, 0, λ}, 
   Assumptions -> {λ > 0, α > 0},
   Method -> "Normalize"];

dpa = DistributionParameterAssumptions[dist]

(* {λ > 0, α > 0} *)

PDF[dist, x]

Assuming[dpa, CDF[dist, x] // Simplify]

data = {2.8, 1.8, 3.2, 5.0, 2.4, 4.8, 2.9, 2.9, 2.3, 3.2, 2.3, 2.0, 1.9, 3.3, 
   4.4, 6.7, 4.3, 1.9, 2.2, 3.3, 2.1, 4.0, 2.0, 3.1, 3.8, 3.1, 3.2, 3.4, 2.8, 
   2.1, 3.1};

mle = FindDistributionParameters[data, dist, 
  ParameterEstimator -> {"MaximumLikelihood", 
    Method -> "FindMaximum", 
    MaxIterations -> 10000}]

(* {α -> 1.09548, λ -> 1.09548} *)

Or more simply,

mle = FindDistributionParameters[data, dist]

(* {α -> 1.09548, λ -> 1.09548} *)

EDIT: The parameter estimates are wrong. As indicated in the comments, different data sets result in identical estimates for the parameters. A bug report was submitted to Wolfram Tech Support (CASE:4954659)