Modify StandardForm of E

Question

StandardForm of E is \[ExponentialE], can we modify it to something else?

I thought I could use MakeBoxes and InterpretationBox like the following:

MakeBoxes[E, StandardForm] := 
 InterpretationBox[StyleBox[ "ℰ", FontColor -> #], E] &@Orange

But as we can see, it doesn't work as expected. The method does work for simpler case, though:

MakeBoxes[a, StandardForm] := 
 InterpretationBox[StyleBox[ "α", FontColor -> #], a] &@Orange

What's wrong with my attempt? What's the correct way to modify StandardForm of E?

Answer 1

Simply due to definition priority mechanism.

Each of these three works:

GeneralUtilities`BlockProtected[E,
  E /: MakeBoxes[E, StandardForm] := 
    InterpretationBox[StyleBox["ℰ", FontColor -> #], E] &@Orange;
]
E

GeneralUtilities`BlockProtected[E,
  E/:MakeBoxes[E, _]=.;
];
MakeBoxes[E, StandardForm] := 
  InterpretationBox[StyleBox["ℰ", FontColor -> #], E] &@Orange
E

GeneralUtilities`BlockProtected[E,
  Format[E, StandardForm] := 
    Interpretation[Style[ "ℰ", FontColor -> Orange], E]
]
E

We can see that a Format definition precedes a MakeBoxes definition (this is documented), and the one bound to E precedes the one bound to MakeBoxes

---

To revert the changes:

GeneralUtilities`BlockProtected[E,
  MakeBoxes[E, StandardForm]=.;
  E/:MakeBoxes[E, StandardForm]=.;
  Format[E, StandardForm]=.;
  E/:MakeBoxes[E, _]:="\[ExponentialE]"
] //Quiet