3
$\begingroup$

If $\left(x_{0},y_{0}\right)\in\left(0,\infty\right)\times\left(0,\infty\right)$, then it easy to get $\left(u_{0},v_{0}\right)\in\left(0,\infty\right)\times\left(0,1\right)$ though the parametric equations $$u=x+y\quad\textrm{and}\quad v=\frac{x}{x+y}.$$

So I tried running the below code:

Region[ParametricRegion[{{x + y, x/(x + y)}, 0 < x && 0 < y}, {x, y}],Axes -> True, AxesOrigin -> {0, 0}]

but I got the below region:

enter image description here

Why the region does not coincide with $\left\{\left(u,v\right):0<u \wedge 0<v<1 \right\}$? Could you please help me diagnose this issue?

Improve this question
$\endgroup$

1 Answer 1

Reset to default
3
$\begingroup$
  • Since we can only plot a mapping from a finite region to another finite region. And by default, we map a finite rectangle to another region which the boundary may not be a rectangle.
ani = Manipulate[
  GraphicsRow[{ParametricPlot[{x, y}, {x, 0, c}, {y, 0, c}, 
     Mesh -> 10, PlotStyle -> Yellow, MeshStyle -> Cyan, 
     BoundaryStyle -> Red, PlotRange -> Automatic], 
    ParametricPlot[{x + y, x/(x + y)}, {x, 0, c}, {y, 0, c}, 
     Mesh -> 10, PlotStyle -> Yellow, MeshStyle -> Cyan, 
     BoundaryStyle -> Red, PlotRange -> {{0, 6}, {0, 1}}, 
     PerformanceGoal -> "Quality"]}, ImageSize -> Full], {c, 1, 8}]

enter image description here

  • If we want the region be a rectangle,we need to limit the range domain be a triangle. ImplicitRegion[{x > 0, y > 0, x + y <= c}, {x, y}]
c = 10; 
GraphicsRow[{ParametricPlot[{x, y}, {x, y} ∈ 
    ImplicitRegion[{x > 0, y > 0, x + y <= c}, {x, y}], Mesh -> 10, 
   MeshFunctions -> {#3 + #4 &}, PlotStyle -> Yellow, 
   MeshStyle -> Cyan, BoundaryStyle -> Red, PlotRange -> Automatic], 
  ParametricPlot[{x + y, x/(x + y)}, {x, y} ∈ 
    ImplicitRegion[{x > 0, y > 0, x + y <= c}, {x, y}], Mesh -> 10, 
   MeshFunctions -> {#3 + #4 &}, PlotStyle -> Yellow, 
   MeshStyle -> Cyan, BoundaryStyle -> Red, PlotRange -> All]}, 
 ImageSize -> Full]

enter image description here

Appendix

FunctionBijective[{{x + y, x/(x + y)}, x > 0 && y > 0, 
  u > 0 && 0 < v < 1}, {x, y}, {u, v}]

True

FunctionRange[{{x + y, x/(x + y)}, x > 0, y > 0, x + y > 0}, {x, 
   y}, {u, v}, Reals] // Simplify

u > 0 && v > 0 && v < 1

Improve this answer
$\endgroup$
1
  • 1
    $\begingroup$ Thanks for your help.Yes,indeed,this transformation $\psi :\mathbb{R^2}\rightarrow\mathbb{R^2}$ $$\psi(x,y)=(x+y,\frac{x}{x+y})$$ is one-to-one on a unit square $\mathcal{R}=\{(x,y):0<x<1,0<y<1\}$ and maps the region $\mathcal{R}$ in the $xy$-plane onto the non-retangle $\mathcal{R^*}=\{(u,v):0<uv<1,0<u(1-v)<1\}$ in the $uv$-plane. $\endgroup$
    – AplehKevin
    Commented Jan 29, 2022 at 7:36

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.