How can I convert dot product into Latex code without dot?

Question

Recently I need to convert a lot of expressions containing dot products into Latex code. To my annoyance, the mathematica system will always leave literal dots (".") in the latex code, but in reality the dot is mostly omitted in Latex code.

For example, I need to convert this matrix into its latex code:

MatrixForm[{{Transpose[X] . X, Transpose[X] . Subscript[x, 0]}, {Transpose[Subscript[x, 0]] . X, Transpose[Subscript[x, 0]] . Subscript[x, 0]}}]

---

(Sorry I have to add a picture of the code since the web site keeps notifying me that "Your post appears to contain code that is not properly formatted as code. Please indent all code by 4 spaces using the code toolbar button or the CTRL+K keyboard shortcut. For more editing help, click the [?] toolbar icon. " and prevented me from posting if I contain the original code. I have tried to follow the instructions but nothing has done the trick.)

What I get from directly converting it into Latex code:

But generally, the dot "." generated from dot product is not needed in Latex, what I want is:

Then, how can I tell Mathematica not to generate the dot "." when convert a dot product into its Latex code?

Answer 1

Try this:

TeXForm[MatrixForm[{{Transpose[X].X, 
     Transpose[X].Subscript[x, 0]}, {Transpose[Subscript[x, 0]].X, 
     Transpose[Subscript[x, 0]].Subscript[x, 0]}}] /. Dot[a_, b_] -> a b]


(* \left(
\begin{array}{cc}
 X X^T & x_0 X^T \\
 X \left(x_0\right){}^T & x_0
   \left(x_0\right){}^T \\
\end{array}
\right)  *)

wich gives the following

Have fun!

Answer 2

Assuming you're using TeXForm, you could do:

expr = {
    {Transpose[X] . X,Transpose[X] . Subscript[x,0]},
    {Transpose[Subscript[x,0]] . X,Transpose[Subscript[x,0]] . Subscript[x,0]}
};

Block[{Dot},
    Dot /: MakeBoxes[Dot[a_,b_], TraditionalForm] := MakeBoxes[Row[{a,b}],TraditionalForm];
    ToString[expr, TeXForm]
]

$$ \left( \begin{array}{cc} X^TX & X^Tx_0 \\ \left(x_0\right){}^TX & \left(x_0\right){}^Tx_0 \\ \end{array} \right) $$

Update

Another possibility is to use the code from my answer to Change TeXForm of ArcTan, reproduced here:

Initial /: Verbatim[TagSetDelayed][Initial[sym_], lhs_, rhs_] := With[
    {
    new = Block[{sym},
        TagSetDelayed[sym, lhs, rhs];
        First @ Language`ExtendedDefinition[sym, "ExcludedContexts" -> {}]
    ],
    protect = Unprotect[sym]
    },

    sym;
    Replace[new,
        Rule[values_, n:Except[{}]] :> (
            values[sym] = DeleteDuplicates@Join[n, values[sym]]
        ),
        {2}
    ];
    Protect@protect;
]

Initial[Convert`TeX`ExpressionToTeX] /: 
    Convert`TeX`ExpressionToTeX[e__] /; !TrueQ@$TeX := Block[
{$TeX = True},
        Convert`TeX`ExpressionToTeX[e]
    ]

Initial[Format] /: TagSetDelayed[sym_Symbol, Verbatim[Format][x_, TeXForm], rhs_] := With[
    {fmt = TraditionalForm},

    Initial[sym] /: MakeBoxes[x, fmt] /; $TeX := MakeBoxes[rhs, fmt]
]

Initial[Format] /: SetDelayed[Verbatim[Format][x_, TeXForm], rhs_] := With[
    {s = getTagSymbol[Format[x, TeXForm]], fmt = TraditionalForm},
    Replace[s,
        HoldForm[tag_] :> (
            Initial[tag] /: MakeBoxes[x, fmt] /; $TeX := MakeBoxes[rhs, fmt]
        )
    ]
]

SetAttributes[getTagSymbol, HoldFirst]

getTagSymbol[Format[x_, TeXForm]] := Module[{dummy, t},
    extractTag[Hold[Message[Format::tag, HoldForm@Format, _, tag_], False]] := t = tag;
    Internal`HandlerBlock[{Message, extractTag},
        Quiet[dummy[1] /: Format[x, TeXForm] := 1]
    ];
    t
]

Then, you can define a new TeXForm for Dot:

Format[Dot[a_, b_], TeXForm] := Row[{a, b}]

Now, using "copy as Latex" should also work.