unexpected StringCases behaviour inside function module

Question

First, Let use see

a = {"wx", "wy", "wz"};
AssociationThread[Flatten[StringCases[a, "w" ~~ d_ :> d]] -> a]

gives

<|"x" -> "wx", "y" -> "wy", "z" -> "wz"|>

Now comes the weird thing. Define

ClearAll[test];
test[] := Module[{a},
  a = {"wx", "wy", "wz"};
  AssociationThread[Flatten[StringCases[a, "w" ~~ d_ :> d]] -> a]
  ]

and run test[], gives

<|d -> "wz"|>

Why?

If you look at the test[]//Trace, you will find "w" ~~ d$_ :> d appears. What is d$_?

If we define

ClearAll[test];
test[] := Module[{},
  a = {"wx", "wy", "wz"};
  AssociationThread[Flatten[StringCases[a, "w" ~~ d_ :> d]] -> a]
  ]

or

ClearAll[test];
test[] := Module[{a,dList},
  a = {"wx", "wy", "wz"};
  dList = Flatten[StringCases[a, "w" ~~ d_ :> d]];
  AssociationThread[dList -> a]
  ]

then test[] gives correct answer.

Can someone explain the above behaviour? How could Module a variable affect the rule replacement of d?

Answer 1

This is a long-standing scoping issue. While we do not have a full resolution, often these can be addressed by a non-default system option setting.

SetSystemOptions["StrictLexicalScoping" -> True];

test[] := Module[{a},
  a = {"wx", "wy", "wz"};
  AssociationThread[Flatten[StringCases[a, "w" ~~ d_ :> d]] -> a]]

In[641]:= test[]

(* Out[641]= <|"x" -> "wx", "y" -> "wy", "z" -> "wz"|> *)