2
$\begingroup$

Let us consider an expression $$\frac{\sqrt[3]{\sqrt{2-x^2}+x} \sqrt[6]{1-x \sqrt{2-x^2}}}{\sqrt[3]{1-x^2}}.$$

Its plot

Plot[Surd[x + Sqrt[2 - x^2], 3]*Surd[1 - x*Sqrt[2 - x^2], 6]/Surd[1 - x^2, 3], {x, -Sqrt[2], Sqrt[2]}, PlotRange -> All]

enter image description here

clearly shows this is Piecewise[{{2^(1/6),x>=-Sqrt[2]&&x<-1||x>-1&&x<1},{-2^(1/6),x>1&&x<=Sqrt[2]}}].

However, my attempts of its simplification

FullSimplify[Surd[x + Sqrt[2 - x^2], 3]*Surd[1 - x*Sqrt[2 - x^2], 6]/Surd[1 - x^2, 3], Assumptions -> x > 1]

and

FullSimplify[Surd[x + Sqrt[2 - x^2], 3]* Surd[1 - x*Sqrt[2 - x^2], 6]/Surd[1 - x^2, 3],Assumptions ->( x >= -Sqrt[2] && x < -1)||(x>-1&&x<1)]

fail.

Knowing the result by substitution x==0 and x==Sqrt[2], the simplification can be established by

Reduce[Surd[x + Sqrt[2 - x^2], 3]*Surd[1 - x*Sqrt[2 - x^2], 6]/Surd[1 - x^2, 3] == 2^(1/6), x, Reals]

-Sqrt[2] <= x < -1 || -1 < x < 1

and

Reduce[Surd[x + Sqrt[2 - x^2], 3]*Surd[1 - x*Sqrt[2 - x^2], 6]/ Surd[1 - x^2, 3] == -2^(1/6), x, Reals]

1 < x <= Sqrt[2]

Is there another way to simplify it in Mathematica?

$\endgroup$

2 Answers 2

1
$\begingroup$

As you have noticed, Reduce is more suitable in this case. But one does not need to know the answer in advance. Can be done as follows.

Define an expression to simplify

f = Surd[x + Sqrt[2 - x^2], 3] Surd[1 - x Sqrt[2 - x^2], 6]/Surd[1 - x^2, 3]

Perform simplification

FullSimplify[Reduce[y == f && #, x, Reals] & /@ FunctionDomain[f, x]]

$$\left(y+\sqrt[6]{2}=0\land 1<x\leq \sqrt{2}\right)\lor \left(y=\sqrt[6]{2}\land \left(-1<x<1\lor -\sqrt{2}\leq x<-1\right)\right)$$

$\endgroup$
4
  • $\begingroup$ +1. This can be simplified; FullSimplify[Reduce[y == f, x, Reals]] results in (2^(1/6) + y == 0 && 1 < x <= Sqrt[2]) || (y == 2^( 1/6) && (-Sqrt[2] <= x < -1 || -1 < x < 1)). $\endgroup$
    – user64494
    Oct 10, 2021 at 8:46
  • $\begingroup$ @user64494 Interesting, I tried it in MA11, but it take too long. I was not patient enough, and therefore, I divided FunctionDomain into subdomains and applied Reduce separately. $\endgroup$
    – yarchik
    Oct 10, 2021 at 8:49
  • $\begingroup$ You may try it in the Wolfram Cloud. I am on 12.3.1. $\endgroup$
    – user64494
    Oct 10, 2021 at 8:52
  • 1
    $\begingroup$ So does Reduce[y == f, x, Reals] // ToRadicals in 12.3.1. $\endgroup$
    – user64494
    Oct 10, 2021 at 8:56
0
$\begingroup$

Here is my answer to the question. We start from

FunctionDomain[Surd[x+Sqrt[2-x^2],3]*Surd[1 - x*Sqrt[2 - x^2], 6]/Surd[1 - x^2, 3],x,Reals]

-Sqrt[2] <= x < -1 || -1 < x < 1 || 1 < x <= Sqrt[2]

Therefore, the domain consists of three intervals. On every one of these intervals the function under consideration is constant. This follows from

FullSimplify[D[Surd[x + Sqrt[2 - x^2], 3]*Surd[1 - x*Sqrt[2 - x^2], 6]/Surd[1 - x^2, 3], x]]

Piecewise[{{0, x*Sqrt[2 - x^2] <= 1}}, Indeterminate]

and

Reduce[x Sqrt[2 - x^2] <= 1, x, Reals]

-Sqrt[2] <= x <= Sqrt[2]

and the mean value theorem. The values of these constants can be found by substitutions x==-Sqrt[2] and x==0 and x==Sqrt[2].

Addition. Another approach consists in

Resolve[ ForAll[x, x > 1 && x <= Sqrt[2], f == c], Reals]//ToRadicals

c == -2^(1/6)

  Resolve[ ForAll[x, x < -1 && x >= -Sqrt[2], f == c], Reals]//ToRadicals

c == 2^(1/6)

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.