Infinite double sum with exclusion

Question

I would like to evaluate the following sum (numerically will suffice): $$ \sum_{m,n=-\infty,(m,n)\neq(0,0)}^{\infty}\frac{1}{m^{4}+n^{4}} $$ I first tried to do $$ \sum_{m,n=1}^{\infty}\frac{1}{m^{4}+n^{4}} $$

NSum[1/(m^4 + n^4), {m, 1, Infinity}, {n, 1, Infinity}]

but got the error "Summand (or its derivative) -((4.\m^3)/(m^4+n^4)^2) is not numerical
at point n = 1.`." I don't understand this as it's a well-behaved, convergent sum. What is going on here?

In terms of the original sum I want to calculate, I'm not sure how to elegantly eliminate the $(m,n)=(0,0)$ term. I thought of using a Kronecker Delta like

NSum[(1 - KroneckerDelta[m, 0] KroneckerDelta[n, 0])/(m^4 + 
    n^4), {m, -Infinity, Infinity}, {n, -Infinity, Infinity}]

but it still complains about the infinite term. How can I avoid this?

Thanks in advance for any help.

Answer 1

Too long for a comment. The double sum under consideration can be treated as an iterated sum and the inner sum has a closed form:

f[n_] := Sum[Piecewise[{{1/(m^4 + n^4), m^2 + n^2 != 0}, {0, 
True}}], {m, -Infinity, Infinity}]
a=Assuming[n\[Element]PositiveIntegers,f[n]]//ComplexExpand

-((\[Pi] Sin[Sqrt[2] n \[Pi]])/( Sqrt[2] n^3 (Cos[Sqrt[2] n \[Pi]] - Cosh[Sqrt[2] n \[Pi]]))) - (\[Pi] Sinh[Sqrt[2] n \[Pi]])/( Sqrt[2] n^3 (Cos[Sqrt[2] n \[Pi]] - Cosh[Sqrt[2] n \[Pi]]))

or in $\LaTeX$ $$-\frac{\pi \sin \left(\sqrt{2} \pi n\right)}{\sqrt{2} n^3 \left(\cos \left(\sqrt{2} \pi n\right)-\cosh \left(\sqrt{2} \pi n\right)\right)}-\frac{\pi \sinh \left(\sqrt{2} \pi n\right)}{\sqrt{2} n^3 \left(\cos \left(\sqrt{2} \pi n\right)-\cosh \left(\sqrt{2} \pi n\right)\right)}$$ and f[0]==\[Pi]^4/45. You may play with it on your own. It's time to go to bed for me.

Answer 2

Divide the index ranges from - Infinity to Infinity into separate sums from - Inf to - 1 and 1 to Inf plus index = 0 and you get partial sums (1/(m^4 + n^4) is even) you can evaluate like

Table[4 (ParallelSum[1./(m^4 + n^4), {m, 1, 10^k}, {n, 1, 10^k}] + 
ParallelSum[1./(m^4), {m, 1, 10^k}]), {k, 1, 4}]
(* {7.34484946634854, 7.375876361817944, 7.3762162344005695, 7.376219664150702} *)

Answer 3

With index pairs {m,n} shown in the plot

the sum is easy evaluated to

4 NSum[1/((m - n)^4 + n^4), {m, 1, Infinity}, {n, 0, m - 1}]
(*7.37602*)