Invalid comparison in Manipulate with Stepwise function

Question

I want to draw a graph of the function that I specified using Piecewise. Though I can draw a graph, I keep getting Min::nord/Max::nord errors saying invalid comparison with -xx + yy I attempted. The followings are my codes.

 ublb1[α_, H_, L_] := 1/2 (2 H - H^2 - 2 L + H L - H α + 2 L α - 
    H L α) - 
 1/2 Sqrt[-4 H^3 + H^4 + 4 H^2 L - 2 H^3 L + H^2 L^2 + 
   4 H^2 α + 2 H^3 α - 6 H^2 L α + 
   2 H^3 L α - 2 H^2 L^2 α - 3 H^2 α^2 + 
   2 H^2 L α^2 + H^2 L^2 α^2]

test[α_, H_, L_] := 
 Piecewise[{{ublb1[α, H, L], 
    0 < L < H < 1 && 
     2 L < H && (H - L)/(1 - H + H^2 - H L) <= α <= (
      H^2 - 2 H L + H^2 L + L^2 - H L^2)/(H^2 - H L + L^2 - H L^2) && 
     ublb1[α, H, L] ∈ Reals && 
     ublb1[α, H, L] <= (1 - α) (1 - H) (H - L)}, {Null, 
    True}}]

Manipulate[
 Plot[{test[α, H, L]}, {α, 0, 1}, AxesOrigin -> {0, 0}, 
  PlotRange -> {0, 1}, AspectRatio -> 1, Frame -> True], {H, 0, 
  1}, {L, 0, H/2}]

I don't understand why I keep getting the errors about the comparison between the complex number and the real number even though I already include the condition ublb1[α, H, L] ∈ Reals && ublb1[α, H, L] <= (1 - α) (1 - H) (H - L).

Thanks for your support in advance.

Answer 1

As the OP points out, the functions are defined in a way that should prevent Min::nord/Max::nord errors. One fix is to add the option Exclusions -> None. When Plot[] examines the function to determine discontinuities, it analyzes piecewise functions. In this case, it seems to allow evaluation when it shouldn’t; or it should do so “secretly” under the cloak of Quiet[]. Probably worth reporting as a potential bug.

Manipulate[
 Plot[{test[α, H, L]}, {α, 0, 1},
  AxesOrigin -> {0, 0}, PlotRange -> {0, 1}, AspectRatio -> 1, 
  Frame -> True, Exclusions -> None],
 {H, 0, 1}, {L, 0, H/2}]

Answer 2

I resolved the issue by re-defining ublb1 as follows.

ublb1[α_, H_, L_] := 
  Piecewise[{{ 
     1/2 (2 H - H^2 - 2 L + H L - H α + 2 L α - 
         H L α) - 
      1/2 Sqrt[-4 H^3 + H^4 + 4 H^2 L - 2 H^3 L + H^2 L^2 + 
        4 H^2 α + 2 H^3 α - 6 H^2 L α + 
        2 H^3 L α - 2 H^2 L^2 α - 3 H^2 α^2 + 
        2 H^2 L α^2 + H^2 L^2 α^2], 
     Im[ 1/2 (2 H - H^2 - 2 L + H L - H α + 2 L α - 
           H L α) - 
        1/2 Sqrt[-4 H^3 + H^4 + 4 H^2 L - 2 H^3 L + H^2 L^2 + 
          4 H^2 α + 2 H^3 α - 6 H^2 L α + 
          2 H^3 L α - 2 H^2 L^2 α - 3 H^2 α^2 + 
          2 H^2 L α^2 + H^2 L^2 α^2]] == 0}, {Null, 
     True}}];