Why Mathematica solves that equation with the solution in complex numbers?

Question

In order to solve the following Euler Differential Equation I write in the notebook:

Assuming[{y∈\[DoubleStruckCapitalR], n>0,x>0},DSolve[x^2 y''[x]+x  y'[x]- n y[x]==0,y[x],x]]

And I get as an output:

{{y[x]->Subscript[[ConstantC], 1] Cosh[Sqrt[n] Log[x]]+I Subscript[[ConstantC], 2] Sinh[Sqrt[n] Log[x]]}}

On the other hand when Mathematica solves the above equation with a specific value for n, for example $n=4$ , it returns the desired solution...

How can I fix this problem, please?

Answer 1

First of all, DSolve does not really take assumptions. (What I mean, DSolve seems to ignore assumptions)

Euler ODE can have 3 different solutions depending on roots $r_1,r_2$ of the characteristic equation. For one repeated root, solution is $y=c_1 x^r+ c_2 x^r \ln x$, and for 2 real and distinct roots, solution is $y=c_1 x^{r_1}+ c_2 x^{r_2}$ and for two complex conjugate roots, solution is $y=c_1 x^{\alpha+i\beta} + c_2 x^{\alpha-i\beta}$

For your case, the roots are $r_1 = -\sqrt{n},r_2 = \sqrt{n}$. Hence for $n>0$ then we are in the second case (2 real distinct roots).

The characteristic equation for Euler ode is found by substituting $y=A x^r$ into the ode and then solving for $r$

You can obtain, for n>0 the solution you want this way

Clear["Global`*"];
ode = x^2 y''[x] + x y'[x] - n y[x] == 0
sol = DSolve[ode, y[x], x]

sol = TrigToExp[sol]

sol = Collect[sol, { x^-Sqrt[n], x^Sqrt[n]}]

We are free to rename constants as we want. Hence

sol = sol /. {C[1]/2 - (I C[2])/2 -> C[3],    C[1]/2 + (I C[2])/2 -> C[4]}

Verify

 ode /. y -> Function[{x}, x^-Sqrt[n] C[3] + x^Sqrt[n] C[4]] // Simplify

 (* True *)

Update

what is the characteristic equation?

Clear["Global`*"];
ode = x^2 y''[x] + x y'[x] - n y[x] == 0;
charEquation = ode /. y -> Function[{x}, A*x^r]

Since $A$ and $x^r$ are non zero, we can divide by them and the above simplifies to

Solve[-  n  +  r + (-1 + r) r == 0, r] 

which gives the solutions

And since $n>0$ then we have two real distinct roots.