1
$\begingroup$

While trying to solve: $$ z \frac{\partial}{\partial z} (z G(s,z))=z \cosh (s) \frac{\partial}{\partial z} G(s,z)-\frac{1}{2} \sinh (s) \frac{\partial}{\partial s} G(s,z) $$ using DSolve it gives a family of solutions:

FullSimplify[
 DSolve[-z D[z G[s, z], 
     z] == - z Cosh[s] D[G[s, z], z] + (1/2) Sinh[s] D[G[s, z], s],
   G, {s, z}]]
(* {{G -> 
   Function[{s, 
     z}, -(((-2 Csch[s]^2 - 2 z Log[Tanh[s/2]] - 
        z Csch[s]^2 Log[Tanh[s/2]] + 
        z Cosh[2 s] Csch[s]^2 Log[Tanh[s/2]]) C[1][(
       Csch[s]^2 (2 - 2 z Cosh[s] + z Log[Tanh[s/2]] - 
          z Cosh[2 s] Log[Tanh[s/2]]))/(2 z)])/z)]}} *)

However I want a specific solution which satisfies:

$$ G(0,z)=\frac{1}{z-1} \;\; \mbox{and} \;\;\frac{\partial}{\partial s}G(s,z) \Big \vert_{s=0}=\frac{\sqrt{z}}{(z-1)^\frac{3}{2}} \;. $$ I do not know how to implement the conditions. Any help is appreciated.

$\endgroup$
1
  • 1
    $\begingroup$ As you see from the solution, the function is not defined for s==0because of the Csch term. Therefore you can not specify G[0,z]. The same pertains to the second condition. $\endgroup$ Jan 26, 2021 at 15:22

1 Answer 1

1
$\begingroup$

Let us suppose that we are interested only in the solution for small s, which seems reasonable, because the question addresses applying boundary conditions at s == 0. Then the PDE becomes

eq = -z D[z G[s, z], z] == -z D[G[s, z], z] + (1/2) s D[G[s, z], s]

and solving it with DSolve yields

G[s, z] -> C[1][Log[-((-1 + z)/(s^2 z))]]/(s^2 z)

i.e., an arbitrary function of Log[-((-1 + z)/(s^2 z))] divided by s^2 z. The problem with this solution is that DSolve does not concern itself with such niceties as branch cuts. If, in the same spirit, I do not worry about branch cuts either, then just a few minutes of thought suggests the solution

 sol = G -> Function[{s, z}, 1/(z - 1) + s Sqrt[z/(z - 1)^3]]

Clearly, it satisfies the the two conditions listed in the question. And, it actually satisfies the PDE, as can be seen from

Simplify[eq/.sol]
(* True *)

Probably this solution is not unique, more general solutions being power series in s Sqrt[z/(z - 1)].

Although I do not have time now to solve the actual PDE posed in the question, I can say with confidence that it does have a solution, and that solution reduces to the one here in the limit of small s.

Addendum: Solution for original PDE

The full PDE in the question,

eq1 = -z D[z G[s, z], z] == -z Cosh[s] D[G[s, z], z] + (1/2) Sinh[s] D[G[s, z], s]

has the solution

DSolve[eq1, G[s, z], {s, z}][[1, 1]]
(* G[s, z] -> (2 Csch[s]^2 C[1][(Csch[s]^2 (2 - 2 z Cosh[s] + 
   z Log[Tanh[s/2]] - z Cosh[2 s] Log[Tanh[s/2]]))/(2 z)])/z *)

obtained using Mathematica "12.2.0 for Microsoft Windows (64-bit) (December 12, 2020)". From this general solution, construct the specific solution

sol1 = G -> Function[{s, z}, 
    1/(z Cosh[s] - 1 + 1/2 z (Cosh[2 s] - 1) Log[Tanh[s/2]]) + 
    Sinh[s] Sqrt[z/(z Cosh[s] - 1 + z/2 (Cosh[2 s] - 1) Log[Tanh[s/2]])^3]];

It satisfies the two constraints,

Series[G[s, z] /. sol1, {s, 0, 0}] // Normal
(* 1/(-1 + z) *)

Series[D[G[s, z] /. sol1, s], {s, 0, 0}] // Normal
(* Sqrt[z/(-1 + z)^3] *)

and, of course, satisfies the PDE.

FullSimplify[eq1 /. sol1]
(* True *)

Note that the solution given is not necessarily the most general one, which would be a power series in Sinh[s] with the two lowest order terms given in sol1. Note also that sol1 may not be analytical at s == 0, but it is continuously differentiable there, which is sufficient for our purposes. For completeness, the characteristic curves of the PDE can be illustrated by

StreamPlot[{Sinh[s]/2, z^2 - z Cosh[s]}, {s, -1, 1}, {z, -1, 1}, 
    StreamScale -> None, StreamColorFunction -> Blue, ImageSize -> Large,
    FrameLabel -> {s, z}, LabelStyle -> {15, Bold, Black}]

enter image description here

A more detailed image can be obtained using the approach illustrated in my answer to 238547.

$\endgroup$
3
  • $\begingroup$ Excellent starting point. Thank you so much. $\endgroup$
    – Ferhat
    Jan 27, 2021 at 7:30
  • 1
    $\begingroup$ @Farhad I have just added the full solution. Best wishes $\endgroup$
    – bbgodfrey
    Jan 27, 2021 at 12:55
  • $\begingroup$ This is fantastic.Thank you for such a wonderful contribution. @bbgodfrey $\endgroup$
    – Ferhat
    Jan 27, 2021 at 19:03

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.