How to find Green function for Laplacian in Upper half plane or first quadrant or left half plane and other regions?

Question

This related to answer Using GreenFunction in 2D free space for Laplacian Where answer there shows how to find Green function for Laplacian in full space.

But what if we want to find Green function for just the upper half plane (subject to homogeneous Dirichlet boundary conditions at y=0)

I looked the function FullRegion used in the answer above and there is no other options to it in change it. I think I need to manually make a region. I looked at ParametricRegion in order to use it in place of FullRegion, but it is not clear to me how to use this function to make a region in the upper half plane for example.

By hand, I find the Green function in upper half using standard method of images. And I wanted to verify my result using Mathematica.

upperHalfPlaneRegion = (*what to write here? Use ParametricRegion?*)
GreenFunction[{-Laplacian[u[x, y], {x, y}], u[x, 0] == 0}, u[x, y], 
      Element[{x, y}, upperHalfPlaneRegion], {ξ, η}]

Btw, to find Green function for Laplacian in upper half using method of images:

gU = GreenFunction[-Laplacian[u[x, y], {x, y}], u[x, y], 
        Element[{x, y}, FullRegion[2]], {x0, y0}];

gL = GreenFunction[-Laplacian[u[x, y], {x, y}], u[x, y], 
       Element[{x, y}, FullRegion[2]], {x0, -y0}];

greenInUpperHalf = gU - gL

I just wanted to see if I get the above result directly by specifying a 'region'.

Using V 12.0

Answer 1

This is a little awkward:

GreenFunction[{-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]},
              u[x, y], {x, y} ∈ HalfPlane[{{0, 0}, {1, 0}}, {0, 1}], {ξ, η}]

   Log[((y + η)^2 + (x - ξ)^2)/((y - η)^2 + (x - ξ)^2)]/(4 π)

Unfortunately, replacing HalfPlane[{{0, 0}, {1, 0}}, {0, 1}] with equivalent (in the sense of RegionEqual[]) region specifications like ImplicitRegion[y >= 0, {x, y}] or HalfSpace[{0, -1}, 0] or even HalfPlane[{0, 0}, {1, 0}, {0, 1}] do not work, so please consider reporting this to support.