0
$\begingroup$

I'd like to test whether this expression is negative when a and b are constrained to lie within (0,1) interval. Any ideas how?

D[Integrate[((1 - (a*x))^12)*((1 + (a/b))/((1 + (a*x/b))^2)), {x, 0, 1}], a]
$\endgroup$
0
$\begingroup$
Clear["Global`*"]

expr1 = ((1 - (a*x))^12)*((1 + (a/b))/((1 + (a*x/b))^2)) // Simplify;

Evaluating the integral

int = Assuming[0 < a <= 1 && 0 < b <= 1,
   Integrate[expr1, {x, 0, 1}] // Simplify];

Taking the derivative

expr2 = D[int, a] // Simplify[#, 0 < a <= 1 && 0 < b <= 1] &;

Numerically finding the minimum

NMinimize[{expr2, 0 < a <= 1, 0 < b <= 1}, {a, b},
  WorkingPrecision -> 20] // N

{-6., {a -> 8.10042*10^-9, b -> 0.91264}}

Limit[expr2, a -> 0]

(* -6 *)

The minimum occurs when a is near 0

Limit[expr2, a -> 0]

(* -6 *)

EDIT: numerically finding the maximum

NMaximize[{expr2, 0 < a <= 1, 0 < b <= 1}, {a, b},
  WorkingPrecision -> 20] // N

(* {-1.00973*10^-12, {a -> 0.981099, b -> 9.7192*10^-13}} *)

The maximum occurs for b near 0

Limit[expr2, b -> 0]

(* 0 *)

Consequently, expr2 is nonpositive everywhere in the region. Graphically,

Plot3D[expr2, {a, 0, 1}, {b, 0, 1},
 PlotPoints -> 50,
 Exclusions -> True,
 WorkingPrecision -> 15,
 ClippingStyle -> None]

enter image description here

$\endgroup$
  • $\begingroup$ Thanks Bob. Shouldn't the last step be a maximization as I want to verify if the expression is always less than 0 e.g. that it's max value < 0? Also do you know why it isn't possible to do analytically rather than numerically? $\endgroup$ – David Zentler-Munro Oct 28 at 14:25
  • $\begingroup$ The expression is transcendental. Terms include product of high order polynomial times a log. Analytic solution is unlikely. $\endgroup$ – Bob Hanlon Oct 28 at 14:45

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.